Comment puis-je ouvrir et enregistrer par programmation une présentation PowerPoint au format HTML/JPEG en C# ou Perl?

Question

Je suis à la recherche d'un extrait de code qui fait juste cela, de préférence en C# ou même en Perl.

J'espère que ce pas une grande tâche;)

Answer 1

Comme Kev rappelle, ne pas utiliser sur un serveur web. Cependant, le script Perl suivant est parfaitement bien pour la conversion de fichiers en ligne etc:

#!/usr/bin/perl 

use strict; 
use warnings; 

use Win32::OLE; 
use Win32::OLE::Const 'Microsoft PowerPoint'; 
$Win32::OLE::Warn = 3; 

use File::Basename; 
use File::Spec::Functions qw(catfile); 

my $EXPORT_DIR = catfile $ENV{TEMP}, 'ppt'; 

my ($ppt) = @ARGV; 
defined $ppt or do { 
    my $progname = fileparse $0; 
    warn "Usage: $progname output_filename\n"; 
    exit 1; 
}; 

my $app = get_powerpoint(); 
$app->{Visible} = 1; 

my $presentation = $app->Presentations->Open($ppt); 
die "Could not open '$ppt'\n" unless $presentation; 

$presentation->Export(
    catfile($EXPORT_DIR, basename $ppt), 
    'JPG', 
    1024, 
    768, 
); 

sub get_powerpoint { 
    my $app; 
    eval { $app = Win32::OLE->GetActiveObject('PowerPoint.Application') }; 
    die "$@\n" if $@; 

    unless(defined $app) { 
     $app = Win32::OLE->new('PowerPoint.Application', 
      sub { $_[0]->Quit } 
     ) or die sprintf(
      "Cannot start PowerPoint: '%s'\n", Win32::OLE->LastError 
     ); 
    } 
    return $app; 
} 

Answer 2

qui suit ouvrira ses portes C:\presentation1.ppt et enregistrer les diapositives que C:\Presentation1\slide1.jpg etc.

Si vous avez besoin pour obtenir l'ensemble de Interop, il est disponible sous "Outils" dans le programme d'installation d'Office, ou vous pouvez le télécharger à partir du here (office 2003). Vous devriez être en mesure de trouver les liens pour d'autres versions à partir de là si vous avez une version plus récente de bureau.

using Microsoft.Office.Core; 
using PowerPoint = Microsoft.Office.Interop.PowerPoint; 

namespace PPInterop 
{ 
    class Program 
    { 
    static void Main(string[] args) 
    { 
     var app = new PowerPoint.Application(); 

     var pres = app.Presentations; 

     var file = pres.Open(@"C:\Presentation1.ppt", MsoTriState.msoTrue, MsoTriState.msoTrue, MsoTriState.msoFalse); 

     file.SaveCopyAs(@"C:\presentation1.jpg", Microsoft.Office.Interop.PowerPoint.PpSaveAsFileType.ppSaveAsJPG, MsoTriState.msoTrue); 
    } 
    } 
} 

Edit: Sinan's version en utilisant l'exportation semble être un peu meilleure option puisque vous pouvez spécifier une résolution de sortie. C#, changer la dernière ligne ci-dessus pour:

file.Export(@"C:\presentation1.jpg", "JPG", 1024, 768);