Utilisation du langage awk pour construire un graphique d'appel de fonction à partir d'un fichier txt contenant des ID de fonction

Question

J'ai un fichier txt avec deux colonnes qui dans chaque colonne j'ai des ID de fonction qui indiquent la première fonction appelle la deuxième fonction comme ci-dessous:

1,4

12,5

4,8

8,1

5,23

Maintenant, je vais utiliser les commandes awk pour trouver un flux de mes appels de fonction. Par exemple, sur la base du contenu ci-dessus de mon fichier, je veux extraire un flux de 1,4,8 et 12,5,23

Pour chaque flux, je vais continuer à ajouter les ID de fonction jusqu'à ce que j'atteigne un cercle ou j'arrive à la fin du fichier. Mes fichiers sont très gros et je ne veux pas utiliser python.

Answer 1

Vous aurez besoin d'un programme descente récursive, comme ceci:

$ cat recurse.awk 
BEGIN { FS=OFS="," } 
{ 
    roots[NR] = $1 
    map[$1] = $2 
} 
END { 
    for (rootNr=1; rootNr<=NR; rootNr++) { 
     root = roots[rootNr] 
     if (!(seen[root]++)) { 
      tree = root 
      descend(root) 
      print tree 
     } 
    } 
} 

function descend(root, branch) { 
    if (root in map) { 
     branch = map[root] 
     if (!(seen[branch]++)) { 
      tree = tree OFS branch 
      descend(branch) 
     } 
    } 
} 

$ awk -f recurse.awk file 
1,4,8 
12,5,23