L'objet Loader ne distribue pas Event.COMPLETE

Question

J'utilise cette classe pour charger plusieurs images de manière synchrone. D'une manière ou d'une autre le chargeur ne déclenche aucun événement (Event.COMPLETE, ProgressEvent.PROGRESS), étrangement je n'obtiens pas non plus d'erreurs (en utilisant FlashDevelop et Flex3 SDK).

package 
{ 
    import flash.display.Loader; 
    import flash.display.Sprite; 
    import flash.events.*; 
    import flash.net.URLRequest; 

    public class MultiImgLoader extends EventDispatcher 
    { 
     private var img_array:Array; 
     public var images:Array; 
     private var loader:Loader = new Loader(); 

     public function MultiImgLoader(img_array:Array) 
     { 
      this.img_array = img_array; 
      trace("[MultiImgLoader] about to load " + img_array.length); 
      if (img_array.length > 0) 
      { 
       load(img_array[0]); 
      } 
     } 

     private function load(img:String):void 
     { 
      trace("[MultiImgLoader] load " + img); 
      loader.addEventListener(ProgressEvent.PROGRESS, progress); 
      loader.addEventListener(Event.COMPLETE, this.ready); 
      var req:URLRequest = new URLRequest(img); 
      loader.load(req); 
     } 

     public function ready(ev:Event):void 
     { 
      var key:String = ev.target.contentLoaderInfo.url; 
      trace("[MultiImgLoader] ready " + key); 
      images.push({ key : ev.target }); 
      if (img_array.length > images.length) 
      { 
       for (var i:int = 0; i < img_array.length; i++) 
       { 
        if (img_array[i] == key) 
        { 
         load(img_array[i+1]); 
        } 
       } 
      } 
     } 

     public function progress(ev:ProgressEvent):void 
     { 
      trace(ev.bytesLoaded); 
     } 

    } 

} 

Answer 1

Ok, c'est compris. Ce:

loader.addEventListener(ProgressEvent.PROGRESS, progress); 
loader.addEventListener(Event.COMPLETE, this.ready); 

devrait lire ceci:

loader.contentLoaderInfo.addEventListener(ProgressEvent.PROGRESS, progress); 
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, ready); 

Je ne sais même pas pourquoi le chargeur-Class a la méthode addEvenListener - tout le monde de redondance?

Answer 2

J'avais quelque chose de similaire, mais j'ai ensuite changé mon chargeur d'un nouveau Loader() en un URLLoader() et cela a fonctionné avec loader.addEventListener.

Cette page m'a aidé: http://livedocs.adobe.com/flex/3/html/help.html?content=17_Networking_and_communications_3.html

Answer 3

J'ai eu même problème avec l'auditeur faible, les travaux réguliers fin

//BUG event not fired 
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onCompleteHandler,false,0,true); 

//OK event fired 
loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onCompleteHandler);