Perl Importer des variables à partir du module d'appel

Question

J'ai un module Perl (Module.pm) qui initialise un certain nombre de variables, dont certaines que je voudrais importer ($ VAR2, $ VAR3) dans des sous-modules supplémentaires qu'il pourrait charger pendant exécution.

La façon dont je suis actuellement en place Module.pm la mise en est comme suit:

package Module; 

use warnings; 
use strict; 

use vars qw($SUBMODULES $VAR1 $VAR2 $VAR3); 

require Exporter; 
our @ISA = qw(Exporter); 
our @EXPORT = qw($VAR2 $VAR3); 

sub new { 
    my ($package) = @_; 
    my $self = {}; 
    bless ($self, $package); 
    return $self; 
} 

sub SubModules1 { 
    my $self = shift; 
    if($SUBMODULES->{'1'}) { return $SUBMODULES->{'1'}; } 

    # Load & cache submodule 
    require Module::SubModule1; 
    $SUBMODULES->{'1'} = Module::SubModule1->new(@_);  
    return $SUBMODULES->{'1'}; 
} 

sub SubModules2 { 
    my $self = shift; 
    if($SUBMODULES->{'2'}) { return $SUBMODULES->{'2'}; } 

    # Load & cache submodule 
    require Module::SubModule2; 
    $SUBMODULES->{'2'} = Module::SubModule2->new(@_);  
    return $SUBMODULES->{'2'}; 
} 

Chaque sous-module est structuré comme suit:

package Module::SubModule1; 

use warnings; 
use strict; 
use Carp; 

use vars qw(); 

sub new { 
    my ($package) = @_; 
    my $self = {}; 
    bless ($self, $package); 
    return $self; 
} 

Je veux être en mesure d'importer le $ Var2 et variables $ VAR3 dans chacun des sous-modules sans avoir à les référencer comme $ Module :: VAR2 et $ Module :: VAR3. J'ai remarqué que le script appelant est capable d'accéder aux deux variables que j'ai exportées dans Module.pm de la manière désirée mais SubModule1.pm et SubModule2.pm doivent toujours faire référence aux variables comme provenant de Module.pm.

J'ai essayé de mettre à jour chaque sous-module comme suit qui ne fonctionne malheureusement j'espérais:

package Module::SubModule1; 

use warnings; 
use strict; 
use Carp; 

use vars qw($VAR2 $VAR3); 

sub new { 
    my ($package) = @_; 
    my $self = {}; 
    bless ($self, $package); 
    $VAR2 = $Module::VAR2; 
    $VAR3 = $Module::VAR3; 
    return $self; 
} 

S'il vous plaît laissez-moi savoir comment je peux exporter avec succès $ et VAR2 $ VAR3 de Module.pm dans chaque sous-module. Merci d'avance pour votre aide!

Answer 1

Dans vos sous-modules, êtes-vous Oublier de dire

use Module; 

? L'appel use Module à partir d'un autre package (par exemple Module::Submodule9) va essayer d'exécuter la méthode Module::import. Puisque vous n'avez pas cette méthode, elle appellera la méthode Exporter::import, et c'est là que la magie qui exporte les variables de Module dans l'espace de noms Module::Submodule9 va arriver.

---

Dans votre programme il n'y a qu'un espace de noms Module et une seule instance de la variable (globale) $Module::VAR2. L'exportation crée des alias pour cette variable dans d'autres espaces de noms, de sorte que la même variable peut être accédée de différentes manières. Essayez ceci dans un script séparé:

package Whatever; 
use Module; 
use strict; 
use vars qw($VAR2); 

$Module::VAR2 = 5; 
print $Whatever::VAR2; # should be 5. 
$VAR2 = 14;    # same as $Whatever::VAR2 = 14 
print $Module::VAR2;  # should be 14 

Answer 2

Eh bien, il est un moyen facile:

En M.pm:

package M; 

use strict; 
use warnings; 

#our is better than "use vars" for creating package variables 
#it creates an alias to $M::foo named $foo in the current lexical scope 
our $foo = 5; 

sub inM { print "$foo\n" } 

1; 

En M/S.pm

package M; 

#creates an alias to $M::foo that will last for the entire scope, 
#in this case the entire file 
our $foo; 

package M::S; 

use strict; 
use warnings; 

sub inMS { print "$foo\n" } 

1; 

Dans le script:

#!/usr/bin/perl 

use strict; 
use warnings; 

use M; 
use M::S; 

M::inM(); 
M::S::inMS(); 

Mais je déconseille cela. Les variables globales ne sont pas une bonne pratique, et le partage des variables globales entre les modules est encore pire.