Comment puis-je lire le contenu d'un fichier dans une liste en Lisp?

Question

Je souhaite lire le contenu d'un fichier dans une liste. Certaines de mes tentatives à ce jour ont été -

(defun get-file (filename) 
    (let ((x (open filename))) 
    (when x 
     (loop for line = (read-line x nil) 
    while line do (list line))) 
    (close x))) 

(defun get-file (filename) 
    (let ((x (open filename :if-does-not-exist nil)) (contents (list nil))) 
    (when x 
     (loop for line = (read-line x nil) 
    while line do (cons contents line))) 
    (close x) contents)) 

(defun get-file (filename) 
    (let ((x (open filename :if-does-not-exist nil)) (contents nil)) 
    (when x 
     (loop for line = (read-line x nil) 
    while line do (append contents line))) 
    (close x) contents)) 

Aucune de ces tentatives. Quelqu'un peut-il me dire un moyen? Ou encore mieux - comment mettre tout le contenu dans un tableau?

Answer 1

Que diriez-vous

(defun get-file (filename) 
    (with-open-file (stream filename) 
    (loop for line = (read-line stream nil) 
      while line 
      collect line))) 

Answer 2

Où sont les problèmes?

(defun get-file (filename) 
    (let ((x (open filename))) 
    (when x 
     (loop for line = (read-line x nil) 
      while line 
      do (list line))) ; <-- you are not collecting, just doing 
    (close x)))     ; <- the function returns the value of CLOSE 

(defun get-file (filename) 
    (let ((x (open filename :if-does-not-exist nil)) 
     (contents (list nil))) 
    (when x 
     (loop for line = (read-line x nil) 
      while line 
      do (cons contents line))) ; <-- again, the cons goes nowhere 
    (close x) contents))    ; <-- CONTENTS has never been changed 

(defun get-file (filename) 
    (let ((x (open filename :if-does-not-exist nil)) 
     (contents nil)) 
    (when x 
     (loop for line = (read-line x nil) 
      while line 
      do (append contents line))) ; <- again the result goes nowhere 
    (close x) contents))     ; <-- CONTENTS has never been changed 

DO va simplement exécuter quelque chose pour les effets secondaires. COLLECT va collecter le résultat et la boucle retournera alors une liste de valeurs collectées à la sortie.

Comme déjà mentionné, utilisez WITH-OPEN-FILE au lieu de OPEN/CLOSE. WITH-OPEN-FILE fermera le fichier en quittant la portée dynamique. Pas seulement à partir d'une sortie normale, mais aussi lors de conditions d'erreur avec UNWIND-PROTECT.

Si vous souhaitez lire le contenu d'un fichier, vous pouvez utiliser READ-SEQUENCE. Avec les problèmes habituels. Par exemple, lorsque vous lisez un fichier ASCII en tant que texte dans une chaîne, la chaîne peut être plus courte que le fichier. Par exemple, Common Lisp représentera CRLF en interne avec un seul caractère, sur les plates-formes où CRLF est en nouvelle ligne. Autre exemple: dans les implémentations supportant Unicode, le code UTF-8 du fichier peut être remplacé par un seul caractère.

Answer 3

Je vais ajouter des bibliothèques dans

modifier encore plus facile, avec uiop, qui est inclus dans ASDF.

(uiop:read-file-lines "file.txt") 

https://github.com/fare/asdf/blob/master/uiop/stream.lisp#L445

a également

(uiop:read-file-string "file") 

---

Avec Alexandria's read-file-into-string et séquence split:

(alexandria:read-file-into-string "file.txt") 
(split-sequence:split-sequence #\Newline *) 

Avec str:

(str:lines (str:from-file "file.txt"))