Comment puis-je dessiner une ligne pointillée dans flex

Question

Après quelques recherches et la lecture du document de classe Graphics, je ne trouve pas un moyen de spécifier le style de ligne d'une ligne. Je veux dire si la ligne est solide ou pointillée. Quelqu'un pourrait-il m'aider?

Merci!

Answer 1

Eh bien il n'y a pas de ligne pointillée ou Dotted flex.

Cependant, vous pouvez créer votre propre ligne ou frontière: http://cookbooks.adobe.com/post_Creating_a_dashed_line_custom_border_with_dash_and-13286.html

Essayez et amusez-vous!

Answer 2

Vous ne pouvez pas, bien, pas simplement en utilisant des classes de bibliothèque Flex de toute façon. Vous pouvez le faire vous-même bien sûr, bien sûr. Voici une classe qui implémente (modifié à partir du code trouvé here, merci Ken Fox):

/*Copyright (c) 2006 Adobe Systems Incorporated 

Permission is hereby granted, free of charge, to any person 
obtaining a copy of this software and associated documentation 
files (the "Software"), to deal in the Software without 
restriction, including without limitation the rights to use, 
copy, modify, merge, publish, distribute, sublicense, and/or sell 
copies of the Software, and to permit persons to whom the 
Software is furnished to do so, subject to the following 
conditions: 

The above copyright notice and this permission notice shall be 
included in all copies or substantial portions of the Software. 

THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, 
EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES 
OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND 
NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT 
HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, 
WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING 
FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR 
OTHER DEALINGS IN THE SOFTWARE. 
*/ 
package com.some.package { 
    import mx.graphics.IStroke; 
    import flash.display.Graphics; 

    public class GraphicsUtils { 
    public static function _drawDashedLine(target:Graphics, strokes:Array, pattern:Array, 
              drawingState:DashStruct, 
              x0:Number, y0:Number, x1:Number, y1:Number):void { 
     var dX:Number = x1 - x0; 
     var dY:Number = y1 - y0; 
     var len:Number = Math.sqrt(dX * dX + dY * dY); 
     dX /= len; 
     dY /= len; 
     var tMax:Number = len; 
     var t:Number = -drawingState.offset; 
     var patternIndex:int = drawingState.patternIndex; 
     var strokeIndex:int = drawingState.strokeIndex; 
     var styleInited:Boolean = drawingState.styleInited; 

     while(t < tMax) { 
     t += pattern[patternIndex]; 
     if(t < 0) { 
      var x:int = 5; 
     } 

     if(t >= tMax) { 
      drawingState.offset = pattern[patternIndex] - (t - tMax); 
      drawingState.patternIndex = patternIndex; 
      drawingState.strokeIndex = strokeIndex; 
      drawingState.styleInited = true; 
      t = tMax; 
     } 

     if(styleInited == false) { 
      (strokes[strokeIndex] as IStroke).apply(target); 
     } 
     else { 
      styleInited = false; 
     } 

     target.lineTo(x0 + t * dX, y0 + t * dY); 

     patternIndex = (patternIndex + 1) % pattern.length; 
     strokeIndex = (strokeIndex + 1) % strokes.length; 
     } 
    } 

    public static function drawDashedLine(target:Graphics, strokes:Array, pattern:Array, 
              x0:Number, y0:Number, x1:Number, y1:Number):void { 
     target.moveTo(x0, y0); 
     var struct:DashStruct = new DashStruct(); 
     _drawDashedLine(target, strokes, pattern, struct, x0, y0, x1, y1); 
    } 

    public static function drawDashedPolyLine(target:Graphics, strokes:Array, pattern:Array, 
               points:Array):void { 
     if(points.length == 0) { return; } 
     var prev:Object = points[0]; 
     var struct:DashStruct = new DashStruct(); 

     target.moveTo(prev.x, prev.y); 

     for(var i:int = 1; i < points.length; i++) { 
     var current:Object = points[i]; 
     _drawDashedLine(target, strokes, pattern, struct, 
         prev.x, prev.y, current.x, current.y); 
     prev = current; 
     } 
    } 
    } 
} 

class DashStruct { 
    public function init():void { 
    patternIndex = 0; 
    strokeIndex = 0; 
    offset = 0; 
    } 
    public var patternIndex:int = 0; 
    public var strokeIndex:int = 0; 
    public var offset:Number = 0; 
    public var styleInited:Boolean = false; 
} 

Et vous pouvez l'utiliser comme:

var points:Array = []; 
points.push({ x: 0, y: 0 }); 
points.push({ x: this.width, y: 0 }); 
points.push({ x: this.width, y: this.height }); 
points.push({ x: 0, y: this.height }); 
points.push({ x: 0, y: 0 }); 

var strokes:Array = []; 
var transparentStroke:Stroke = new Stroke(0x0, 0, 0); 
strokes.push(new Stroke(0x999999, 2, 1, false, 'normal', CapsStyle.NONE)); 
strokes.push(transparentStroke); 
strokes.push(new Stroke(0x222222, 2, 1, false, 'normal', CapsStyle.NONE)); 
strokes.push(transparentStroke); 

GraphicsUtils.drawDashedPolyLine(this.graphics, strokes, [ 16, 5, 16, 5 ], points); 

Answer 3

J'ai couru à travers cela, aujourd'hui, que j'aime beaucoup. Fournit des lignes pointillées/pointillées et quelques autres choses (courbes, principalement).

http://flexdevtips.blogspot.com/2010/01/drawing-dashed-lines-and-cubic-curves.html

Answer 4

je le fais assez simple:

public static function drawDottedLine(target:Graphics, xFrom:Number, yFrom:Number, xTo:Number, yTo:Number, dotLenth:Number = 10):void{ 
    var isGap:Boolean; 
    target.moveTo(xFrom, yFrom); 
    xFrom += dotLenth; 
    for(xFrom; xFrom < xTo; xFrom += dotLenth){ 
     if(isGap){ 
      target.moveTo(xFrom, yFrom); 
     } else { 
      target.lineTo(xFrom, yFrom); 
     } 
     isGap = !isGap; 
    } 
} 

UPD: :) De la même façon que dans le lien fourni par Ross.

Answer 5

j'ai écrit un code de DashedLine simple -

import flash.display.Graphics; 

import spark.primitives.Line; 

public class DashedLine extends Line 
{ 


    public var dashLength:Number = 10; 

    override protected function draw(g:Graphics):void 
    { 
     // Our bounding box is (x1, y1, x2, y2) 
     var x1:Number = measuredX + drawX; 
     var y1:Number = measuredY + drawY; 
     var x2:Number = measuredX + drawX + width; 
     var y2:Number = measuredY + drawY + height;  

     var isGap:Boolean; 

     // Which way should we draw the line? 
     if ((xFrom <= xTo) == (yFrom <= yTo)) 
     { 
      // top-left to bottom-right 
      g.moveTo(x1, y1); 

      x1 += dashLength; 
      for(x1; x1 < x2; x1 += dashLength){ 
       if(isGap){ 
        g.moveTo(x1, y1); 
       } else { 
        g.lineTo(x1, y1); 
       } 
       isGap = !isGap; 
      } 
     } 
     else 
     { 
      // bottom-left to top-right 
      g.moveTo(x1, y2); 


      x1 += dashLength; 
      for(x1; x1 < x2; y2 += dashLength){ 
       if(isGap){ 
        g.moveTo(x1, y2); 
       } else { 
        g.lineTo(x1, y2); 
       } 
       isGap = !isGap; 
      } 


     } 
    } 

} 

utiliser ensuite comme ça -

<comps:DashedLine top="{}" left="0" width="110%" > 
    <comps:stroke> 
     <s:SolidColorStroke color="0xff0000" weight="1"/> 
    </comps:stroke> 
</comps:DashedLine>