Bien sûr, pas de problème:
<xsl:stylesheet
version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
<xsl:output indent="yes" />
<xsl:template match="/data">
<!-- copy the document element -->
<xsl:copy>
<!-- That's where we start: all "record" nodes that have no "\". -->
<xsl:apply-templates mode="recurse" select="/data/record[
not(contains(@Name, '\'))
]" />
</xsl:copy>
</xsl:template>
<xsl:template match="record" mode="recurse">
<xsl:param name="starting-path" select="''" />
<!-- The record node and its ID attribute can be copied. -->
<xsl:copy>
<xsl:copy-of select="@ID" />
<!-- Create the new "name" attribute. -->
<xsl:attribute name="Name">
<xsl:value-of select="substring-after(@Name, $starting-path)" />
</xsl:attribute>
<!-- Append a backslash to the current path. -->
<xsl:variable name="current-path" select="concat(@Name, '\')" />
<!-- Select all "record" nodes that are one level deeper... -->
<xsl:variable name="children" select="/data/record[
starts-with(@Name, $current-path)
and
not(contains(substring-after(@Name, $current-path), '\'))
]" />
<!-- ...and apply this template to them. -->
<xsl:apply-templates mode="recurse" select="$children">
<xsl:with-param name="starting-path" select="$current-path" />
</xsl:apply-templates>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>
sortie sur mon système:
<data>
<record ID="26" Name="category 1">
<record ID="24" Name="sub category 1">
<record ID="25" Name="sub category 2"></record>
<record ID="27" Name="sub category 3"></record>
</record>
</record>
</data>
Notez que la solution entière est basée sur l'hypothèse que tous les chemins sont canoniques et ne contiennent pas antislashs arrière . Notez également que tous les éléments "record" non appariés/orphelins ne seront pas dans la sortie (à moins qu'ils ne soient au niveau de la racine, bien sûr).
Encore une chose: Le mode modèle ("recurse") n'est pas strictement nécessaire. Je l'ai inclus parce que le modèle fait quelque chose de plutôt spécial, et il y a peut-être la possibilité qu'il y ait un autre modèle dans votre solution qui corresponde aux nœuds "record". Dans ce cas, cette solution peut être déposée sans rien casser d'autre. Pour une solution autonome, les modes de modèle peuvent être supprimés à tout moment.
Oh, et la dernière chose: si vous voulez que le document de résultat à commander par nom, incluez un <xsl:sort>
element avec les <xsl:apply-templates>
(deux occurrences), comme suit:
<xsl:apply-templates select="...">
<xsl:sort select="@Name" data-type="text" order="ascending" />
</xsl:apply-templates>
@myso: « sous catégorie 3 "est au même niveau que" sous catégorie 2 "dans votre XML d'entrée. Il ne peut pas être imbriqué comme vous le montrez dans votre fichier XML de sortie. – Tomalak
Oui, mon erreur. L'ai édité. – mysomic