Rechercher par un mémo dans Delphi?

Question

Quelqu'un peut-il me donner un code simple qui me donnerait la possibilité de rechercher une chaîne simple dans un mémo et de le mettre en surbrillance dans le mémo après avoir été trouvé?

Answer 1

function TForm1.FindText(const aPatternToFind: String):Boolean; 
    var 
    p: Integer; 
    begin 
    p := pos(aPatternToFind, Memo1.Text); 
    Result := (p > 0); 
    if Result then 
     begin 
     Memo1.SelStart := p; 
     Memo1.SelLength := Length(aPatternToFind); 
     Memo1.SetFocus; // necessary so highlight is visible 
     end; 
    end; 

Ceci ne recherche PAS entre les lignes si WordWrap est vrai.

Answer 2

Cette recherche permet l'insertion de documents, la recherche sensible à la casse et la recherche à partir de la position du curseur.

type 
    TSearchOption = (soIgnoreCase, soFromStart, soWrap); 
    TSearchOptions = set of TSearchOption; 


function SearchText(
    Control: TCustomEdit; 
    Search: string; 
    SearchOptions: TSearchOptions): Boolean; 
var 
    Text: string; 
    Index: Integer; 
begin 
    if soIgnoreCase in SearchOptions then 
    begin 
    Search := UpperCase(Search); 
    Text := UpperCase(Control.Text); 
    end 
    else 
    Text := Control.Text; 

    Index := 0; 
    if not (soFromStart in SearchOptions) then 
    Index := PosEx(Search, Text, 
     Control.SelStart + Control.SelLength + 1); 

    if (Index = 0) and 
     ((soFromStart in SearchOptions) or 
     (soWrap in SearchOptions)) then 
    Index := PosEx(Search, Text, 1); 

    Result := Index > 0; 
    if Result then 
    begin 
    Control.SelStart := Index - 1; 
    Control.SelLength := Length(Search); 
    end; 
end; 

Vous pouvez définir HideSelection = False sur la note de service pour afficher la sélection même si la note ne se concentre pas.

Utilisez comme ceci:

SearchText(Memo1, Edit1.Text, []); 

Permet la recherche des modifications aussi bien.