J'ai besoin de montrer des données Excel sur une page web ou un document Word présentable?

Question

J'ai des résultats d'enquête qui sont formatés en Excel. J'ai ensuite besoin de montrer ces résultats individuellement avec les titres sur un document doc présentable ou une page wewb? y a-t-il du mal à le faire?

Par exemple:

colonne une - comlumn 2

résultat 1 - suite 1

résultat 2 - suite 2

à

comlumn 1

suite un

colonne 2

un résultat

colonne 1

résultat 2

comlumn 2

résultat 2

désolé si cela n'a pas de sens.

Merci

Answer 1

On dirait que vous avez besoin d'utiliser « publipostage » de l'intérieur mot, puis donner la feuille de calcul Excel comme source de données.

Answer 2

Il n'y a pas beaucoup d'informations dans votre question, mais il semble que vous pourriez utiliser une macro pour transformer vos données. J'ai écrit une macro rapide qui prend des données dans le format que vous avez présenté et les sort comme vous l'avez spécifié.

J'utiliserais la macro ci-dessous pour créer une nouvelle feuille de calcul dans Excel, puis la manipuler ou la coller dans Word si nécessaire. Sans plus d'informations, il n'y a plus rien à dire.

**Input** 
Column A  Column B 
Result A1  Result B1 
Result A2  Result B2 
**Output** 
Column A 
Result A1 
Column B 
Result B1 
Column A 
Result A2 
Column B 
Result B2 

Voici la macro:

' Transforms the current sheet 
' This method takes columns and rows and outputs a 
' single This is not a transpose method, but similar. 
Public Sub TransformSheet() 
    Dim SourceSheet As Worksheet 
    Dim ResultSheet As Worksheet 
    Dim iSourceColumn As Long, iSourceRow As Long 
    Dim iResultColumn As Long, iResultRow As Long 
    Dim iHeaderRow As Long 
    Dim UseCopyPaste As Boolean 
    ' Change source and result sheets as necessary 
    Set SourceSheet = ActiveSheet 
    Set ResultSheet = ActiveWorkbook.Sheets("Sheet2") 
    ' Options 
    UseCopyPaste = True 
    iHeaderRow = 1 
    iResultColumn = 1 
    iResultRow = 1 
    ' Main Loop 
    For iSourceRow = 2 To SourceSheet.UsedRange.Rows.Count 
     For iSourceColumn = 1 To SourceSheet.UsedRange.Columns.Count 
      If UseCopyPaste Then 
       ' Header Column 
       SourceSheet.Cells(iHeaderRow, iSourceColumn).Copy 
       ResultSheet.Cells(iResultRow, iResultColumn).PasteSpecial xlPasteAll 
       iResultRow = iResultRow + 1 
       ' Result Column 
       SourceSheet.Cells(iSourceRow, iSourceColumn).Copy 
       ResultSheet.Cells(iResultRow, iResultColumn).PasteSpecial xlPasteAll 
       iResultRow = iResultRow + 1 
      Else 
       ' Header Column 
       ResultSheet.Cells(iResultRow, iResultColumn) = _ 
        SourceSheet.Cells(iHeaderRow, iSourceColumn).Value 
       iResultRow = iResultRow + 1 
       ' Result Column 
       ResultSheet.Cells(iResultRow, iResultColumn) = _ 
        SourceSheet.Cells(iSourceRow, iSourceColumn).Value 
       iResultRow = iResultRow + 1 
      End If 
     Next iSourceColumn 
    Next iSourceRow 
End Sub