avec sortie xslt

Question

Dans le fichier .xml, j'ai comme ceci:

<function>true</function> 

Dans le schéma ile, je l'ont défini comme une valeur booléenne. Alors maintenant, ça fonctionne correctement. MAIS pour le fichier XSLT-à-dire .xsl,

Answer 1

Vous pouvez utiliser xsl:choose:

<td> 
    <xsl:choose> 
    <xsl:when test="function = 'true'">@</xsl:when> 
    <xsl:otherwise>&#32;</xsl:otherwise> 
    </xsl:choose> 
</td> 

Answer 2

Cela peut se faire très simplement, pas du tout exigeant des instructions XSLT conditionnelles, et tout à fait dans l'esprit du XSLT (push-style):

Cette transformation:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="function/text()[.='true']">@</xsl:template> 
<xsl:template match="function/text()[not(.='true')]"> 
    <xsl:text> </xsl:text> 
</xsl:template> 

<xsl:template match="function"> 
    <td><xsl:apply-templates/></td> 
</xsl:template> 
</xsl:stylesheet> 

lorsqu'il est appliqué sur le document XML suivant:

<function>true</function> 

produit le résultat souhaité, correct:

<td>@</td> 

Lorsque la même transformation est appliquée sur le document XML suivant:

<function>false</function> 

à nouveau la bonne, résultat recherché est produit:

<td> </td> 

Enfin, en utilisant un hack (en XSLT 2.0/XPath 2.0 est pas nécessaire), on peut utiliser un seul modèle:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
     <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="function"> 
    <td> 
    <xsl:value-of select= 
    "concat(substring('@', 1 div (.='true')), 
      substring(' ', 1 div not(.='true')) 
     ) 
    "/> 
    </td> 
</xsl:template> 
</xsl:stylesheet>