Comment lancer une version particulière de Xcode à partir d'Applescript?

Question

J'ai deux versions de Xcode, Xcode 3.2.3 et l'aperçu du développeur Xcode4. Comment puis-je m'assurer d'Applescript que la version 3.2.3 est choisie?

Answer 1

Au lieu de Xcode référencement simplement par son nom, à savoir:

tell application "Xcode" 
    ... 
end tell 

vous pouvez également faire référence à une version particulière d'une application par son chemin POSIX complet, à savoir:

tell application "/Developer/Applications/Xcode 3.2.3.app" 
    ... 
end tell 

Voir aussi la Section du guide linguistique AppleScript sur le application class.

Une solution plus complexe consiste à rechercher dans la base de données des services de lancement pour toutes les versions d'une application installées sur le système. Vous pouvez alors choisir une programmation avec la version requise:

property pLSRegisterPath : "/System/Library/Frameworks/CoreServices.framework/Versions/A/Frameworks/LaunchServices.framework/Versions/A/Support/lsregister" 
property pAppBundleID : "com.apple.Xcode" 
property pAppRequiredVersion : "3.2.3" 

set theAppPaths to every paragraph of (do shell script pLSRegisterPath & " -dump | grep --before-context=2 \"" & pAppBundleID & "\" | grep --only-matching \"/.*\\.app\"") 

set xcodeApp to missing value 
repeat with theAppPath in theAppPaths 
    try 
     if (version of application theAppPath) = pAppRequiredVersion then 
      set xcodeApp to application theAppPath 
      exit repeat 
     end if 
    end try 
end repeat 

if xcodeApp = missing value then 
    error "Needed application version not installed." 
end if 

using terms from application "Xcode" 
    tell xcodeApp 
     activate 
    end tell 
end using terms from 

Answer 2

Vous pouvez lancer une application par son identifiant comme celui-ci. Peut-être que les deux versions auront des identifiants différents.

tell application id "com.apple.AddressBook" 
    -- do something 
end tell 

Vous pouvez obtenir un id de l'application de cette ...

tell application "Finder" to return id of (choose file)