Comment obtenir des données de TextArea pour les enregistrer dans Winword et le bloc-notes?

Pour une partie de ma tâche de script, je dois créer un formulaire html qui permet à l'utilisateur d'entrer des données dans une zone de texte qui peut ensuite être enregistrée en tant que document Word ou Notepad dans le lecteur: H en utilisant HTA. La partie HTML du formulaire était très facile, mais j'ai du mal à la faire fonctionner de sorte que le fait de cliquer sur l'un des boutons enregistre les données au bon endroit. Jusqu'à présent, j'ai travaillé sur l'obtention du premier bouton pour enregistrer le fichier dans Word pour commencer à travailler, mais je suis franchement désemparé quant à savoir où aller à partir d'ici. Voici le code que j'ai pour l'instant:Comment obtenir des données de TextArea pour les enregistrer dans Winword et le bloc-notes?

<html> 
<head> 
<HTA:APPLICATION> 

<script type="text/javascript" language="javascript"> 
function SaveFile() 
{ 
wordApp = new ActiveXObject("Word.Application"); 
wordApp.Visible = true; 
} 
</script> 
</head> 
<body> 
<form> 
Enter your information: 
<br /> 
<textarea cols="40" rows="12"> 
</textarea> 
<br /> 
<input type="button" value="save into word" id="Word.Application" /> 
<input type="button" value="save into notepad" /> 
</form> 
</body> 
</html>

Pourrais-je obtenir de l'aide avec ceci? Merci d'avance.

Source

2017-09-23 Paraiyar

Eh bien il vous manque un événement qui déclenche une action. Dans ce cas "onClick". WhereClick appelle votre fonction SaveFile. Je conseillerais d'avoir une fonction de sauvegarde générique qui, en fonction de la valeur transmise à la fonction SaveFile, déterminerait quelle application est utilisée pour enregistrer vos données (vous pouvez utiliser l'une des structures conditionnelles pour cela).

onClick="SaveFile('notepad')" //saves data in notepad 

onClick="SaveFile('word')" //saves data in word

Source

2017-09-23 04:25:08

Vous pouvez donner un essai pour cette HTA:

<html> 
<Title>Save file into noteapd and Word Application</Title> 
<META HTTP-EQUIV="MSThemeCompatible" CONTENT="YES"> 
<head> 
<HTA:APPLICATION 
ICON="Notepad.exe" 
APPLICATIONNAME = "Save file into noteapd and Word Application" 
BORDER="dialog" 
BORDERSTYLE="complex" 
> 
</head> 
<script type="text/Vbscript"> 
'***************************************************** 
Sub window_onload() 
    CenterWindow 500,350 
End Sub 
'***************************************************** 
Sub CenterWindow(x,y) 
    Dim iLeft,itop 
    window.resizeTo x,y 
    iLeft = window.screen.availWidth/2 - x/2 
    itop = window.screen.availHeight/2 - y/2 
    window.moveTo ileft,itop 
End Sub 
'***************************************************** 
Sub Save2Word() 
'Create and Save a Word Document 
Title = "Data saved into Word Appplication" 
FileDoc = "C:\" & Month(Date) & "_" & Day(Date) & "_" & Year(Date) & ".doc" 
Set objWord = CreateObject("Word.Application") 
objWord.Visible = False 
Txtarea = document.all("Txtarea").Value 
Set objDoc = objWord.Documents.Add() 
Set objSelection = objWord.Selection 
objSelection.Font.Name = "Comic Sans MS" 
objSelection.Font.Size = "12" 
objSelection.TypeText Txtarea 
objDoc.SaveAs(FileDoc) 
objWord.Quit 
MsgBox "Data saved into : " & FileDoc,vbInformation,Title 
End Sub 
'***************************************************** 
Sub Save2Notepad() 
'Save into a Notepad Document 
Title = "Data saved into Notepad Appplication" 
Set fso = CreateObject("Scripting.FileSystemObject") 
FileTxt = "C:\" & Month(Date) & "_" & Day(Date) & "_" & Year(Date) & ".txt" 
Txtarea = document.all("Txtarea").Value 
Set oFile = fso.OpenTextFile(FileTxt,8,true) 
oFIle.WriteLine Txtarea 
oFile.Close 
MsgBox "Data saved into : " & FileTxt,vbInformation,Title 
End Sub 
'***************************************************** 
</script> 
<body> 
<center> 
<form> 
Enter your information: 
<br> 
<textarea ID="Txtarea" NAME="Txtarea" cols="40" rows="12"></textarea> 
<hr> 
<input type="button" value="save into word" onClick="Save2Word()"/> 
<input type="button" value="save into notepad" onClick="Save2Notepad()"/> 
<hr> 
</form> 
</center> 
</body> 
</html>

Source

2017-09-25 11:07:23 Hackoo

Comment obtenir des données de TextArea pour les enregistrer dans Winword et le bloc-notes?

Répondre

Questions connexes