Parcourez plusieurs identifiants possibles TCL Expect

Question

J'ai écrit un script pour vous connecter via ssh et exécuter des commandes. La moitié des appareils sur la liste de ma liste d'appareils ont une combinaison de nom d'utilisateur et de mot de passe acceptable différente.

Je veux attendre à pouvoir interpréter l'échec de connexion, lancez une nouvelle tentative de connexion avec le même appareil, mais utilisent des identifiants de connexion à la deuxième tentative (il y a deux combinaisons nom d'utilisateur et mot de passe possibles)

Si n'importe qui peut me diriger dans la bonne direction, je l'apprécierais vraiment. C'est ma première fois en utilisant TCL ou attendre.

Une version condensée de ce que j'ai jusqu'ici est ci-dessous.

set username "someusername" 
set password "somepassword" 

set devices "X.X.X.X" 

foreach device $devices { 
    puts "Processing device: $device"; 
    spawn plink -ssh $devices 

    expect "Store key in cache" 
    send "y\r" 

    expect "login as:" 
    send "$username\r" 

    expect "password:" 
    send "$password\r" 
    expect "#" 

send "conf t\r" 
expect "(config)#" 

send "some commands\r" 
expect "(config)#" 

send "end\r" 
expect "#" 

send "copy run startup-config\r" 
expect "#" 

Answer 1

Vous devez probablement quelque chose comme

set usernames [list name1 name2] 
set passwords [list pw1 pw2 ] 

set devices [list X.X.X.X ...] 

foreach device $devices { 
    puts "Processing device: $device"; 
    spawn plink -ssh $devices 

    set auth_idx -1 

    expect { 
     "Store key in cache" {send "y\r"; exp_continue} 

     "login as:" { 
      incr auth_idx 
      if {$auth_idx == [llength $usernames]} { 
       puts "login failed for $device" 

       # close the plink connection. I'm guessing here 
       send \003  ;# Ctrl-C 
       expect eof 

       # and on to the next device 
       continue 
      } 

      send "[lindex $usernames $auth_idx]\r" 
      expect "password:" 
      send "[lindex $passwords $auth_idx]\r" 

      # and wait for either the command prompt or another login prompt 
      exp_continue 
     } 

     "#" 
    } 

    # ... whatever you do when you're logged in 

    # and logout. something like 
    send "quit\r" 
    expect eof 
} 

Il utilise exp_continue à "boucle" dans le même s'attendre à déclaration. Je suppose que vous ne devez pas toujours stocker la clé dans le cache. Je suppose que vous voyez « se connecter comme » si la première tentative de connexion échoue

---

MISE À JOUR

set usernames [list name1 name2] 
set passwords [list pw1 pw2 ] 

set devices [list X.X.X.X ...] 

set device_idx 0 
set auth_idx 0 

while {$device_idx < [llength $devices]} { 
    set device [lindex $devices $device_idx] 

    puts "Processing device: $device"; 
    spawn plink -ssh $devices 

    expect { 
     "Store key in cache" {send "y\r"; exp_continue} 

     "login as:" { 
      send "[lindex $usernames $auth_idx]\r" 
      expect "password:" 
      send "[lindex $passwords $auth_idx]\r" 
      exp_continue 
     } 

     "Access denied" { 
      incr auth_idx 
      if {$auth_idx == [llength $usernames]} { 
       puts "login failed for $device" 
       # next device 
       set auth_idx 0 
       incr device_idx 
      } else { 
       # close the plink connection. I'm guessing here 
       send \003  ;# Ctrl-C 
       expect eof 
       # re-do with current device 
      } 
      continue 
     } 

     "#" 
    } 

    # ... whatever you do when you're logged in 

    # and logout. something like 
    send "quit\r" 
    expect eof 

    # and on to the next device 
    set auth_idx 0 
    incr device_idx 
}