Importer des fichiers .xml tous Schtasks à l'intérieur du répertoire courant par lot

Question

Je sais qu'il est possible d'importer plusieurs tâches comme ceci:

schtasks.exe /create /TN "Task 1 Name" /XML "Full_Path_of_Backup_XML_File" 
schtasks.exe /create /TN "Task 2 Name" /XML "Full_Path_of_Backup_XML_File" 
schtasks.exe /create /TN "Task 3 Name" /XML "Full_Path_of_Backup_XML_File" 

Mais je préfère une façon plus dynamique d'importer les fichiers de tous Schtasks intérieur le répertoire actuel. Tout comme this lot ici (.xml au lieu de .reg):

rem @echo off 
cls 
SET folder=%~dp0 
for %%i in ("%folder%*.reg") do (regedit /s "%%i") 
echo done 
pause 
EXIT 

Quelqu'un peut-il me guider vers la bonne direction? :)

Answer 1

Voulez-vous dire que vous voulez parcourir tous les fichiers XML situés dans le même répertoire que le script de traitement par lots? Et puis créer une tâche planifiée avec chaque fichier XML trouvé? Si tel est le cas, vous pouvez essayer quelque chose comme ça (en supposant que les fichiers XML sont valides pour créer des tâches planifiées avec):

@echo off 

setlocal enabledelayedexpansion 

for %%e in ("%~dp0*.xml") do (
    set /a "count+=1" 
    schtasks /create /tn "Task !count! Name" /xml "%%~e" 
) 

---

Si vous devez être en mesure de transmettre des noms de fichiers XML qui contiennent des points d'exclamation à l'outil de ligne de commande schtasks, utilisez plutôt le code suivant:

@echo off 

setlocal disabledelayedexpansion 
set "count=1" 

for %%e in ("%~dp0*.xml") do (
    set "file=%%~e" 
    setlocal enabledelayedexpansion 
    schtasks /create /tn "Task !count! Name" /xml "!file!" 
    endlocal & set /a "count+=1" 
) 

---

encore une question, comment nommer le ta sks aiment leurs noms de fichiers .xml?

Cela fait de simplifier les choses parce qu'il n'y a pas besoin de développer une variable distincte dans le corps pour en boucle pendant le temps d'exécution:

@echo off 

setlocal disabledelayedexpansion 

for %%e in ("%~dp0*.xml") do (
    schtasks /create /tn "%%~ne" /xml "%%~e" 
)