Ping script avec boucle et enregistrer dans un txt

Question

Je tente de faire un script Ping avec vbs. J'ai besoin d'un script, ce ping (aucune limite de ping, le programme s'exécutera tout le temps) un nom d'ordinateur dans le réseau toutes les 2 secondes et enregistrer les résultats dans un fichier txt.

Par exemple:

06/08/2010 - 13:53:22 | L'ordinateur "..." est en ligne

06/08/2010 - 13:53:24 | L'ordinateur « ... » est déconnecté

Maintenant, j'essayer un peu:

strComputer = "TestPC" 

    Set objPing = GetObject("winmgmts:{impersonationLevel=impersonate}")._ 
    ExecQuery("select * from Win32_PingStatus where address = '"_ 
    & strComputer & "'") 
    For Each objStatus in objPing 
    If IsNull(objStatus.StatusCode) Or objStatus.StatusCode <> 0 Then 

    ..........   

    Next 

Et que je ne sais pas comment le faire. (Je suis nouveau avec vbs :-))

J'espère que quelqu'un peut m'aider.

saluer, matthias

Answer 1

Essayez cette

Option Explicit 

Dim strHost, strFile 

strHost = "www.google.com" '"127.0.0.1" 
strFile = "C:\Test.txt" 

PingForever strHost, strFile 

Sub PingForever(strHost, outputfile) 
    Dim Output, Shell, strCommand, ReturnCode 

    Set Output = CreateObject("Scripting.FileSystemObject").OpenTextFile(outputfile, 8, True) 
    Set Shell = CreateObject("wscript.shell") 
    strCommand = "ping -n 1 -w 300 " & strHost 
    While(True) 
     ReturnCode = Shell.Run(strCommand, 0, True)  
     If ReturnCode = 0 Then 
      Output.WriteLine Date() & " - " & Time & " | The Computer " & strHost & " is online" 
     Else 
      Output.WriteLine Date() & " - " & Time & " | The Computer " & strHost & " is offline" 
     End If 
     Wscript.Sleep 2000 
    Wend 
End Sub 

Answer 2

vous mettez votre pings dans une boucle de quelque sorte et puis utilisez Wscript.Sleep 2000 dormir pendant 2 secondes.

Ensuite, vous utilisez le File System Object (FSO) pour écrire dans un fichier. L'information peut être trouvée here.

Edit: Quelque chose comme cela pourrait fonctionner:

Const OpenFileForAppending = 8 
Dim fso, ts 
Set fso = CreateObject("Scripting. FileSystemObject") 

While 1 > 0 ' loop forever  
    Set ts = fso.OpenTextFile("c:\temp\test.txt", OpenFileForAppending, True) 

    ' do your pinging code 

    'if ok 
     ts.WriteLine("OK") 
    'else 
     ts.WriteLine("Not OK") 
    'endif 

    ts.Close() 
    Wscript.Sleep 2000 
Wend