VBA: Coller cesse de travailler (soudainement) dans une macro spécifique

Question

Je suis un tout nouveau programmeur autodidacte, alors gardez cela à l'esprit dans vos réponses. J'ai beaucoup cherché ceci et d'autres forum et ne peux pas sembler trouver une question semblable.

Le code suivant a fonctionné pendant des semaines et n'a pas été modifié. (Ma macro inclut plus de variables et de code, mais je sais que je les démonte pour que ces pièces fonctionnent, donc je les ai laissées pour plus de clarté). De ce que je peux dire la fonction PasteSpecial est spécifiquement ne fonctionne pas.

Dim StimSheet As String 

ActiveCell.Rows("1:290").EntireRow.Select 
Selection.Copy 
'Copies the data for the current stimulus 
StimSheet = Application.InputBox("Enter the name of the stimulus") 
'asks name of the stimulus 

Sheets.Add After:=Worksheets(Worksheets.Count) 
ActiveSheet.Name = StimSheet 
'adds new sheet at the end and names whatever you input as stimulus name 

Sheets(StimSheet).Select 
Selection.PasteSpecial Paste:=xlPasteValues 
'pastes data into new sheet 

À ce stade, il n'y a pas d'erreur, la macro s'arrête simplement après la copie et la création de la nouvelle feuille.

Voici ce que je sais/ont essayé:

1. La macro fait et nommer avec succès la nouvelle feuille et la copie la sélection dans le presse-papiers, parce que je peux coller manuellement après l'exécution de la macro. Il semble être coincé à la pièce de pâte.

2. D'autres macros qui utilisent exactement le même format de copier/coller spécial fonctionnent toujours correctement.

3. Un autre forum avec un programme similaire a suggéré de taper "Application.EnableEvents = True" dans la fenêtre immédiate. Cela n'a rien changé.

4. Cette macro a fonctionné pendant plusieurs semaines sans erreur. J'ai fait de nouvelles macros en utilisant du code précédemment sauvegardé au cas où quelque chose aurait été modifié par inadvertance dans le courant, mais cela n'a pas fonctionné non plus.

5. L'option de collage fonctionnera une fois sur un nouveau fichier, puis cessera de fonctionner à nouveau.

Merci d'avance pour vos suggestions.

Answer 1

Vous pourriez trouver que le problème est que vous n'avez pas beaucoup de contrôle sur le classeur et la feuille de calcul auxquels ce code s'applique. Il est préférable d'éviter ActiveSheet, Select, et Sheet sans parent autant que vous le pouvez.

Si vous avez seulement besoin de copier les valeurs des cellules sans aucun formatage, alors Paste n'est pas nécessaire non plus.

Essayez de changer votre code à la suivante et voir si vous avez plus de chance:

Const BOOK_NAME As String = "Book1.xlsm" 'change this to your workbook name 
Const SOURCE_SHEET_NAME As String = "Sheet1" 'change this to your sheet name 
Dim wb As Workbook 
Dim sourceSheet As Worksheet 
Dim newSheet As Worksheet 
Dim newSheetName As String 
Dim validName As Boolean 
Dim rng As Range 

' Set the book, sheet and range objects 
Set wb = Workbooks(BOOK_NAME) 
Set sourceSheet = wb.Worksheets(SOURCE_SHEET_NAME) 
Set newSheet = wb.Worksheets.Add(After:=wb.Worksheets(wb.Worksheets.Count)) 

' Acquire the new sheet name and check it's valid. 
Do 
    newSheetName = InputBox("Enter the name of the stimulus") 
    On Error Resume Next 
    newSheet.Name = newSheetName 
    validName = (Err.Number = 0) 
    On Error GoTo 0 
    If Not validName Then MsgBox "Sheet name isn't valid. Try again." 
Loop Until validName 

' Write the values into the new sheet 
Set rng = sourceSheet.Cells(1, 1).Resize(290, sourceSheet.UsedRange.Columns.Count) 
newSheet.Range(rng.Address).value = rng.Value2 

Answer 2

je me suis déplacé cette ligne:

StimSheet = Application.InputBox("Enter the name of the stimulus") 

au sommet de la méthode et il semble fonctionner de manière fiable. Je voudrais pouvoir vous dire exactement pourquoi, mais au moins vous pouvez continuer. Peut-être que cela a quelque chose à voir avec le changement d'orientation.

Aussi, quand il a échoué pour moi (Office 2013) J'obtenu l'erreur suivante:

Erreur d'exécution 1004: application défini ou un objet défini erreur.

Lorsque le sous-marin était dans un code de feuille derrière, et ceci:

Erreur d'exécution '1004' méthode PasteSpecial de classe Range a échoué.

Collé dans un module.