Quelle est la syntaxe appropriée pour stocker un tableau dans un hachage Perl?

Question

Je crée un nouvel objet comme celui-ci:

TestObject->new(@array1, @array2) 

Ma méthode new ressemble à ceci:

sub new { 
    my $class = shift; 
    my $self = {}; 

    my $self->{Array1} = shift; 
    my $self->{Array2} = shift; 

    bless($self, $class); 

    return $self; 
} 

En tant que test simple pour accéder aux données, j'essaie cela, puis une fois que je le faire fonctionner, je peux construire une logique plus significative:

sub mymethod { 
    my $self = shift; 
    my $param = shift; 

    my $array1Value = shift(my $self->{Array1}); 
    my $array2Value = shift(my $self->{Array2}); 

    print $array1Value." ".$array2Value; 
} 

Mais quand je l'appelle mymethod, je reçois cette erreur:

Type of arg 1 to shift must be array (not hash element) at Tests/MyObject.pm line 21, near "})" 

Suggestions? J'ai lu this page on Perl data structures, mais ils n'ont pas d'exemples pour créer un hachage de tableaux en utilisant les arguments d'une méthode utilisant shift. Donc, mon problème pourrait être là.

Answer 1

vous devez derefernece ref tableau:

@{$self->{Array2}} 

Par ailleurs, si vous utilisez OO Je suggère avec insistance que vous regardez dans Moose. Cela rendra votre vie beaucoup plus facile!

Answer 2

Lorsque vous transmettez des tableaux en tant que paramètres, ils sont aplatis. Vous pouvez passer des références à eux. Voir perlsub

#!/usr/bin/env perl 

package foo; 

sub new { 
    my $class = shift; 
    my $self = {}; 

    $self->{Array1} = shift; 
    $self->{Array2} = shift; 

    bless($self, $class); 

    return $self; 
} 

sub mymethod { 
    my $self = shift; 
    my $param = shift; 

    my $array1Value = shift(@{$self->{Array1}}); 
    my $array2Value = shift(@{$self->{Array2}}); 

    print "$array1Value $array2Value\n"; 
} 

package main; 

my @a = (0, 1, 2); 
my @b = (3, 4, 5); 
my $o = new foo(\@a, \@b);; 
$o->mymethod; 

Answer 3

vous devez utiliser des pointeurs vers des tableaux, pas de tableaux dans ce cas:

TestObject->new([@array1], [@array2]) 

puis plus tard

my $array1Value = shift(@{$self->{Array1}}); 

Answer 4

Vous décalant un arrayref au lieu d'un véritable tableau.

La syntaxe ytou're probablement à la recherche est:

my $array1Value = shift @{ $self->{Array1} }; 
my $array2Value = shift @{ $self->{Array2} }; 

Notez comment le tableau est déréférencé en utilisant @.