Utilisation de Clojure pour tester l'unité Java

Question

L'une des façons d'amener une organisation à accepter un langage JVM alternatif est de l'utiliser d'abord pour tester les unités de code Java - "Boss, je vais juste écrire des tests unitaires dans XXX. Ça ne sortira jamais en production. "

Existe-t-il des didacticiels pour faire cela dans Clojure?

Je viens de commencer à utiliser Scala pour tester un serveur Java REST. L'écriture des tests dans Scala me permet d'intégrer la sortie XML attendue, de mocker les appels de base de données avec des objets littéraux List, sans oublier que les traits rendent très facile l'extraction du code commun pour les tests.

Answer 1

Fondamentalement, ce dont vous avez besoin est clojure.test (ou l'une des nombreuses autres bibliothèques de test clojure) et standard Clojure Java interop.

Exemple:

(ns example.test-java-util 
    (:use 
    [clojure.test]) 
    (:import [java.util HashSet])) 

(defn new-empty-set [] 
    (HashSet.)) 

(deftest test-empty-set 
    (is (= 0 (.size (new-empty-set)))) 
    (is (= true (.isEmpty (new-empty-set)))) 
    (is (= (new-empty-set) (new-empty-set)))) 

(deftest test-add-remove 
    (is (= (new-empty-set) 
     (doto (new-empty-set) 
      (.add "xyz") 
      (.remove "xyz"))))) 

Et alors vous les exécuter dans une variété de façons. Construire des outils comme Maven en utilisant le plugin maven clojure les exécuter automatiquement dans le cadre du "test mvn". Dans un rempl, vous pouvez faire quelque chose comme:

example.test-java-util> (run-tests 'example.test-java-util) 

Testing example.test-java-util 

Ran 1 tests containing 4 assertions. 
0 failures, 0 errors. 
{:type :summary, :test 1, :pass 4, :fail 0, :error 0} 

Answer 2

Voici un exemple d'utilisation Leiningen, test.check et en supposant une mise en page standard Maven:

pom.xml 
project.clj 
src 
    main 
    java 
     quicktest 
     Discontinuities.java 
    test 
    clojure 
     quicktest 
     test_discontinuities.clj 

La fonction Java à tester:

package quicktest; 
public class Discontinuities { 
    public static double f5(double x) { 
     return x/(x-5); 
    } 
} 

Le scénario de test Clojure:

(ns quicktest.test-discontinuities 
    (:import [quicktest Discontinuities]) 
    (:require [clojure.test :refer :all] 
    [clojure.test.check :as tc] 
    [clojure.test.check.generators :as gen] 
    [clojure.test.check.properties :as prop] 
    [clojure.test.check.clojure-test :as ct :refer (defspec)])) 

(deftest test-single-case 
    (is (= 2.0 (Discontinuities/f5 10)))) 

(defspec test-discontinuities 1e4 
     (prop/for-all [x gen/nat ] 
         (let [y (Discontinuities/f5 x)] 
          (is (<= y x))))) 

Le projet:

(defproject quicktest/discontinuities "0.1" 
      :dependencies [[org.clojure/clojure "1.8.0"] 
          [org.clojure/test.check "0.9.0"]] 
      :java-source-paths ["src/main/java"] 
      :test-paths ["src/test/clojure"]) 

Le pom:

<?xml version="1.0" encoding="UTF-8"?> 
<project xmlns="http://maven.apache.org/POM/4.0.0" 
     xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" 
     xsi:schemaLocation="http://maven.apache.org/POM/4.0.0 http://maven.apache.org/xsd/maven-4.0.0.xsd"> 
    <modelVersion>4.0.0</modelVersion> 
    <groupId>quicktest</groupId> 
    <artifactId>discontinuities</artifactId> 
    <version>0.1</version> 
</project> 

Run avec:

mvn compile 
lein deps 
lein test 

Résultats

La faille dans la fonction est vite trouvée:

FAIL in (test-discontinuities) (test_discontinuities.clj:13) 
expected: (<= y x) 
actual: (not (<= Infinity 5)) 
{:test-var "test-discontinuities", 
:result false, 
:seed 1431128331945, 
:failing-size 23, 
:num-tests 24, 
:fail [5], 
:shrunk {:total-nodes-visited 3, :depth 0, :result false, :smallest [5]}}