Référence case à cocher nom/valeur dans un sous-programme

Question

Existe-t-il un moyen de transmettre une valeur de case à cocher à partir d'un formulaire utilisateur? Je l'ai vu quand la case à cocher est sur la feuille de travail, mais je n'ai pas réussi à la faire fonctionner quand elle vient de mon userform.

J'ai plusieurs instructions if répétitives et la seule différence entre elles est le nom de la case à cocher. Je suis sûr qu'il y a une solution simple que je n'ai pas encore trouvée. Toute aide est appréciée.

Edit: inclus Code

If LockboxCheckBox.Value = True Then 
    If IsEmpty(wsInput.Cells(emptyRow, productCol)) Then 
     wsInput.Cells(emptyRow, productCol).Value = LockboxCheckBox.Caption 
    Else: wsInput.Cells(emptyRow, productCol).Value = wsInput.Cells(emptyRow, productCol).Value & ", " & LockboxCheckBox.Caption 
    End If 
End If 

Je veux faire un petit sous-programme et le besoin de passer checkbox.value ainsi que le checkbox.caption à quand je l'appelle.

Answer 1

L'exemple de code suivant montre comment passer un contrôle Checkbox sur un objet UserForm à une autre procédure, obtenir la valeur et la légende de la case à cocher et faire quelque chose avec eux.

Notez que je choisis de passer la case, plutôt que la valeur et la légende, comme deux paramètres, car cela réduira la quantité de code que vous devez taper.

Private Sub btnOK_Click() 
    Dim chk As MSForms.CheckBox 
    Set chk = Me.CheckBox1 
    ProcessCheckBox chk 
    ProcessCheckBox Me.CheckBox2 
End Sub 

Sub ProcessCheckBox(chk As MSForms.CheckBox) 
    Dim chkVal As Boolean 
    Dim chkCap As String 

    chkVal = chk.value 
    chkCap = chk.Caption 
    If chkVal = True Then 
     Debug.Print chkCap & " is true" 
    Else 
     Debug.Print chkCap & " is false" 
    End If 
End Sub