XML à l'aide de l'analyse syntaxique XML :: LibXML

Question

Voici les données de l'échantillon qui essaie d'analyser pour en extraire la valeur d'attribut correspondant au noeud Société: CID, Nom, Symbole, valeur pour tous les nœuds de l'entreprise sous le nœud sociétés

<?xml version="1.0" encoding="UTF-8"?> 
<StockRecords xmlns="http://url1" 
       xmlns:ref="http://url2" 
       xmlns:xsi="http://url3"> 
    <Companies> 
    <Company> 
     <CID>123</CID> 
     <Name>Google</Name> 
     <Symbol>GOOG</Symbol> 
     <Value>1234</Value> 
    </Company> 
    </Companies> 
</StockRecords> 

Voici les 2 variantes que j'ai essayées. Variante 1

use XML::LibXML; 

my $filename = "test.xml"; 
my $dom = XML::LibXML->load_xml(location => $filename); 

foreach my $sample ($dom->findnodes('/Companies/Company')) { 

    print Dumper($sample); 
    last; 
} 

Variante 2: Comme il y a des espaces de noms qui y participent, XPathContext à préciser.

use XML::LibXML; 

my $filename = "test.xml"; 
my $parser = XML::LibXML->new(); 
my $xmldoc = $parser->parse_file($filename); 

my $root = $xmldoc->getDocumentElement; 

my @l = $root->getElementsByTagName('StockRecords'); 

my $xc = XML::LibXML::XPathContext->new($root); 

$xc->registerNs("ns1", "http://url1"); 
$xc->registerNs("ref", "http://url2"); 
$xc->registerNs("xsi", "http://url3"); 

Je ne peux pas extraire de données pour un attribut du noeud. J'ai jeté un oeil à d'autres réponses, la documentation LibXML encore il y a quelque chose qui manque. S'il vous plaît aidez-moi avec quelques pointeurs. Merci

Answer 1

use strict; 
use warnings; 
use feature qw(say); 

use XML::LibXML    qw(); 
use XML::LibXML::XPathContext qw(); 

my $doc = XML::LibXML->load_xml(location => $ARGV[0]); 

my $xpc = XML::LibXML::XPathContext->new(); 
$xpc->registerNs(ns1 => "http://url1"); 

for my $company_node ($xpc->findnodes("/ns1:StockRecords/ns1:Companies/ns1:Company", $doc)) { 
    say $xpc->findvalue("ns1:CID", $company_node); 
    say $xpc->findvalue("ns1:Name", $company_node); 
}