Ajouter du temps à la norme ISO 8601 fois en Perl

Question

je ISO 8601 le temps stocké dans une variable et j'ai un certain nombre d'heures stockées dans une autre variable comme ceci:

my $current_time = shift; #looks like: 2015-07-01T15:38:08Z 
my $hours = shift; # looks like: 12 

Mon but est d'ajouter les heures à l'heure actuelle, mais il ne semble pas y avoir de fonction Perl intégrée pour le faire. Dans Powershell, vous pouvez faire quelque chose comme ceci:

$currentTime = $currentTime .AddHours($hours) 

Y a-t-il un moyen facile de faire cela en Perl?

Answer 1

plutôt facile avec Time::Piece:

#! /usr/bin/perl 
use warnings; 
use strict; 

use Time::Piece; 
use Time::Seconds; 

my $current_time = '2015-07-01T15:38:08Z'; 
my $hours = 12; 

my $format = '%Y-%m-%dT%H:%M:%SZ'; 
my $time = 'Time::Piece'->strptime($current_time, $format); 
$time += $hours * ONE_HOUR; 

print $time->strftime($format), "\n"; 

Answer 2

Ce profil spécifique ISO 8601 est également connu sous le nom RFC3339.

use DateTime::Format::RFC3339; 

my $dt = DateTime::Format::RFC3339->parse_datetime('2015-07-01T15:38:08Z'); 
$dt->add(hours => 1); 
print "$dt\n"; # 2015-07-01T16:38:08Z 

Si vous souhaitez accepter arbitraire des profils ISO 8601, vous pouvez utiliser DateTime :: Format :: ISO8601.

use DateTime::Format::ISO8601; 

my $dt = DateTime::Format::ISO8601->parse_datetime('2015-07-01T15:38:08Z'); 
$dt->set_time_zone('UTC'); # Convert to UTC ("Z") if it's not already. 
$dt->add(hours => 1); 
print $dt->iso8601().'Z', "\n"; # 2015-07-01T16:38:08Z 

J'ai publié ces alternatives parce que ces modules sont beaucoup moins sujettes aux erreurs que Time :: Piece.

Answer 3

Vous pouvez également utiliser Time::Moment. Dans l'intérêt de la divulgation complète, je suis l'auteur de Time :: Moment.

say Time::Moment->from_string('2015-07-01T15:38:08Z') 
       ->plus_hours(1); 

Sortie:

2015-07-01T16:38:08Z