comment enregistrer des données à partir de ms acess front end à ms sql backend?

Question

comment enregistrer des données à partir de ms acess front end à ms sql backend?

Answer 1

Il est presque toujours préférable d'utiliser des tables liées. Cela rend la vie beaucoup plus facile, car vous pouvez mettre à jour les tables et les vues SQL Server plus ou moins de la même manière que vous mettez à jour une table Access. Un autre bon moyen est d'utiliser des requêtes de passe: http://support.microsoft.com/kb/303968

Cela étant dit, voici quelques notes brutes.

La meilleure façon d'obtenir une chaîne ODBC utile est de lier une table à l'aide de l'assistant, vous pouvez le regarder à l'aide CurrentDB.TableDefs("NameOfLinkedTable").Connect

Vous pouvez utiliser la chaîne comme ceci:

Dim db As Database 
Set db = CurrentDb 

strConnect = "ODBC;Description=Test;DRIVER=SQL Server;" _ 
      & "SERVER=ServerAddress;Trusted_Connection=Yes;DATABASE=DBName" 

strSQL = "INSERT INTO [" & strConnect & "].[SomeSQLServerTable] (ID, AText) " _ 
     & "SELECT a.ID, a.Descr FROM SomeAccessTable As a " _ 
     & "LEFT JOIN [" & strConnect & "].[SomeSQLServerTable] s " _ 
     & "ON s.ID=a.ID " _ 
     & "WHERE s.ID Is Null" 

db.Execute strSQL, dbFailOnError 
Debug.Print db.RecordsAffected 

Vous peut également mettre à jour avec ADO. Il y a beaucoup d'informations se trouvent ici: http://msdn.microsoft.com/en-us/library/ms130978.aspx Vous pouvez obtenir des chaînes de connexion ici: http://www.connectionstrings.com/

Et quelques-unes des choses bizarres que vous pouvez faire:

Dim cn As New ADODB.Connection 
Dim RecsAffected As Long 
Dim scn As String, sSQL As String 

''Using SQL Server connection native client 
scn = "Provider=SQLNCLI10;Server=ServerAddress;" _ 
    & "Database=DBName; Trusted_Connection=yes;" 

cn.Open scn 

sSQL = "INSERT INTO NewSQLServerTable " _ 
    & "SELECT * FROM OPENROWSET " _ 
    & "('Microsoft.ACE.OLEDB.12.0','C:\docs\ltd.mdb';'Admin';, " _ 
    & "'SELECT * FROM OldAccessTable')" 

cn.Execute sSQL, RecsAffected 

Debug.Print RecsAffected 

Ou

Dim cn As New ADODB.Connection 
Dim RecsAffected As Long 
Dim scn As String, sSQL As String 

''Using Jet connection 
Set cn = CurrentProject.Connection 

strConnect = "ODBC;Description=Test;DRIVER=SQL Server;" _ 
      & "SERVER=ServerAddress;Trusted_Connection=Yes;DATABASE=DBName" 

sSQL = "INSERT INTO [" & strConnect & "].NewSQLServerTable " _ 
    & "SELECT * FROM OldAccessTable" 

cn.Execute sSQL, RecsAffected 


''Using Jet & an external mdb 
sSQL = "INSERT INTO [" & strConnect & "].NewSQLServerTable " _ 
    & "SELECT * FROM OldAccessTable IN " _ 
    & "'C:\docs\ltd.mdb'" 

cn.Execute sSQL, RecsAffected 

Debug.Print RecsAffected