Impression de l'ensemble de paires valeur/clé à l'intérieur d'un élément XML à l'aide de XSLT

Pour un noeud XML donné, il faut que j'obtienne les paires valeur/clé. Pour un exemple:Impression de l'ensemble de paires valeur/clé à l'intérieur d'un élément XML à l'aide de XSLT

XML:

<root> 
    <detail1> 
     <test1> Text1 </test1> 
     <test2> Text2 </test2> 
     <test3> Text3 </test3> 
    </detail1> 
    <detail2> description 1 </detail2> 
    <detail3> description 2 </detail3> 
</root>

je besoin d'un tableau comme suit (Ignorer le plus haut sommet élément):

 

detail1 | test1 : Text1 
     | test2 : Text2 
     | test2 : Text3 
     | 
detail2 | description 1 
     | 
detail3 | description 2

Est-ce possible avec XSLT? Si quelqu'un peut me montrer un exemple ou une ressource, ce serait très utile.

Source

2010-11-05 sanjayav

Quel est le format de la table voulez-vous, HTML? – LarsH

oui j'ai besoin d'un tableau HTML. – sanjayav

Bonne question, +1. Voir ma réponse pour une solution complète et courte qui est entièrement dans l'esprit de XSLT (utilise le style push). C'est la seule réponse jusqu'à présent qui produit exactement la sortie désirée. –

Cette transformation:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="text"/> 
<xsl:strip-space elements="*"/> 

<xsl:variable name="vBlanks" select="'       '"/> 

<xsl:template match="/*/*"> 
    <xsl:value-of select="concat('&#xA;', name(), ' | ')"/> 
    <xsl:apply-templates/> 
</xsl:template> 

<xsl:template match="/*/*/*"> 
    <xsl:value-of select="concat(name(), ' : ')"/> 
    <xsl:apply-templates/> 
</xsl:template> 

<xsl:template match="/*/*/*[not(position()=1)]"> 
    <xsl:text>&#xA;</xsl:text> 
    <xsl:value-of select="substring($vBlanks,1,string-length(name(..))+1)"/> 
    <xsl:value-of select="concat('| ', name(), ' : ')"/> 
    <xsl:apply-templates/> 
</xsl:template> 
</xsl:stylesheet>

lorsqu'il est appliqué sur le document XML fourni:

<root> 
    <detail1> 
     <test1> Text1 </test1> 
     <test2> Text2 </test2> 
     <test3> Text3 </test3> 
    </detail1> 
    <detail2> description 1 </detail2> 
    <detail3> description 2 </detail3> 
</root>

produit le résultat souhaité, correct:

detail1 | test1 : Text1 
     | test2 : Text2 
     | test3 : Text3 
detail2 | description 1 
detail3 | description 2

Source

2010-11-05 12:57:01

merci beaucoup pour cette solution. – sanjayav

Vous devriez regarder Print XML tag names and values in Java. L'idée principale est de nommer() et text() fonctions et la construction du format devrait être relativement facile

Source

2010-11-05 06:41:15 Fazal

Oui. Vous avez besoin de la balise for-each qui vous permet de parcourir le résultat d'une expression XPath. Voir http://www.w3schools.com/xsl/xsl_for_each.asp pour une explication et un cas d'utilisation.

Source

2010-11-05 06:41:49

J'aime utiliser xsl: apply-templates mieux que d'utiliser xsl: for-each.

Edit: changé clause de correspondance de*[text()]à*[count(text()) = 1]

Si vous appliquez cette transformation

<?xml version="1.0"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

    <xsl:template match="/"> 
    <html> 
     <table> 
     <xsl:apply-templates select="root/*"/> 
     </table> 
    </html> 
    </xsl:template> 

    <xsl:template match="*[count(text()) = 1]"> 
    <tr> 
     <td> 
     <xsl:value-of select="name()"/> 
     </td> 
     <td> 
     <xsl:value-of select="."/> 
     </td> 
    </tr> 
    </xsl:template> 

    <xsl:template match="*"> 
    <xsl:apply-templates select="*" mode="keyvalue"/> 
    </xsl:template> 

    <xsl:template match="*" mode="keyvalue"> 
    <tr> 
     <xsl:choose> 
     <xsl:when test="position() = 1"> 
      <td> 
      <xsl:value-of select="name(..)"/> 
      </td> 
      <td> 
      <xsl:call-template name="formatkeyvalue"/> 
      </td> 
     </xsl:when> 
     <xsl:otherwise> 
      <td></td> 
      <td> 
      <xsl:call-template name="formatkeyvalue"/> 
      </td> 
     </xsl:otherwise> 
     </xsl:choose> 
    </tr> 
    </xsl:template> 

    <xsl:template name="formatkeyvalue"> 
    <xsl:value-of select="concat(name(), ' : ', text())"/> 
    </xsl:template> 

</xsl:stylesheet>

à votre entrée, vous obtenez

<html> 
    <table> 
    <tr> 
     <td>detail1</td> 
     <td>test1 : Text1 </td> 
    </tr> 
    <tr> 
     <td></td> 
     <td>test2 : Text2 </td> 
    </tr> 
    <tr> 
     <td></td> 
     <td>test3 : Text3 </td> 
    </tr> 
    <tr> 
     <td>detail2</td> 
     <td> description 1 </td> 
    </tr> 
    <tr> 
     <td>detail3</td> 
     <td> description 2 </td> 
    </tr> 
    </table> 
</html>

Source

2010-11-05 09:26:17 cfern

C'est exactement ce que je voulais. Mais quand j'exécute ceci, la table générée manque des valeurs de test1, de test2, de test3. Je suis très nouveau à xslt. Pouvez-vous me donner un indice sur ce qui pourrait être le problème? Merci d'avance. – sanjayav

@sunnyj: bizarre. J'ai développé la solution avec Xselerator et cela a fonctionné (excellent outil, au fait). Après avoir lu votre commentaire, j'ai re-testé la transformation en studio visuel et il a échoué comme vous l'avez décrit. Intéressant, mais ennuyeux. Je pense que j'ai trouvé ce qui l'a causé et mis à jour ma réponse.Est-ce que ça marche? – cfern

Cette feuille de style:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:template match="/*"> 
     <table border="1px"> 
      <xsl:apply-templates/> 
     </table> 
    </xsl:template> 
    <xsl:template match="/*/*"> 
     <tr> 
      <td> 
       <xsl:value-of select="name()"/> 
      </td> 
      <td> 
       <xsl:apply-templates/> 
      </td> 
     </tr> 
    </xsl:template> 
    <xsl:template match="/*/*/*"> 
     <xsl:value-of select="concat(name(),' : ')"/> 
     <xsl:apply-templates/> 
     <xsl:if test="following-sibling::*"> 
      <br/> 
     </xsl:if> 
    </xsl:template> 
</xsl:stylesheet>

Sortie:

<table border="1px"> 
    <tr> 
     <td>detail1</td> 
     <td>test1 : Text1 
      <br />test2 : Text2 
      <br />test3 : Text3 
     </td> 
    </tr> 
    <tr> 
     <td>detail2</td> 
     <td> description 1 </td> 
    </tr> 
    <tr> 
     <td>detail3</td> 
     <td> description 2 </td> 
    </tr> 
</table>

Source

2010-11-05 13:03:04

je vous remercie beaucoup pour cette solution. – sanjayav

@sunnyj: Vous êtes bienvenu. –

Impression de l'ensemble de paires valeur/clé à l'intérieur d'un élément XML à l'aide de XSLT

Répondre

Questions connexes