Conversion UCS2 (Unknown LE ou BE) au format numérique Hex UTF-8 En utilisant Perl

Question

espérant que quelqu'un peut me diriger dans la direction de l'endroit où je vais mal avec ceci:

J'ai une chaîne de (ce que Je crois) est UCS2 hexadécimal, mais le fournisseur ne peut pas me dire si c'est UCS2-LE ou UCS2-BE.

comme ceci: 0627062E062A062806270631

Il se traduit par ceci: اختبا

En arabe apparemment ... mais personne ne importe si j'essayez de le convertir sur six pans, en utilisant comme UCS2 droite (LE ou BE) ou pratiquement tout ce que je peux penser sous le soleil, je ne peux pas le transformer en natif-perl UTF-8 afin que je puisse ensuite ré-encoder comme UTF-8 standard (format natif de notre système).

code:

my $string = "0627062E062A062806270631"; 
my $decodedHex = hex($string); 

#NEAREST 
my $perlDecodedUTF8 = decode("UCS-2BE", $decodedHex); 
my $utf8 = encode('UTF-8',$perlDecodedUTF8); 

open(ARABICTEST,">ucs2test.txt"); 
print(ARABICTEST $perlDecodedUTF8); 
print("Done!"); 
close(ARABICTEST); 

Il émet des caractères incompréhensibles pour le moment. Maintenant, une idée que je suis venu avec était de diviser la chaîne en question en sections de 4 caractères (c'est-à-dire par code hexadécimal), mais même en essayant cela avec une valeur hexadécimale UCS2 connue ne semble pas fonctionner.

Également essayé de forcer le codage de sortie, pas de joie là non plus.

Merci!

Answer 1

hex n'est pas le moyen de décoder une chaîne hexadécimale en une séquence d'octets. pack est. (hex produit un seul entier, pas une chaîne d'octets.) A part ça, vous étiez proche. Essayez ceci:

use strict; 
use warnings; 
use Encode; 

my $string = "0627062E062A062806270631"; 
my $decodedHex = pack('H*', $string); 

my $perlDecodedUTF8 = decode("UCS-2BE", $decodedHex); 

open(my $ARABICTEST,">:utf8", "ucs2test.txt"); 
print $ARABICTEST $perlDecodedUTF8; 
print("Done!"); 
close($ARABICTEST); 

Remarque: Vous souhaitez probablement utiliser UTF-16BE au lieu de UCS-2BE. Ils sont fondamentalement la même chose, mais UTF-16BE autorise les paires de substitution, et pas UCS-2BE. Donc tout le texte UCS-2BE est également valide UTF-16BE, mais pas vice versa.