Comment savoir si un hachage Perl est multidimensionnel?

Question

En supposant que j'ai un hachage comme ceci:

$hash_ref = { 

    'hashes' => { 
    'h1' => { 'klf' => '1', 'moomooland' => '1' }, 
    'h2' => { 'klf' => '2', 'moomooland' => '2' }, 
    'h3' => { 'klf' => '3', 'moomooland' => '3' } 
    }, 

    'keys' => { 
    'k1' => 'key1', 
    'k2' => 'key2', 
    'k3' => 'key3' 
    } 

} 

Comment pourrais-je savoir, aussi facile que possible, que hashes contient 3 plus hash, tandis que keys contient 3 paires clé/valeur?

ref retournera HASH pour les deux, et je ne suis pas sûr s'il est possible de trouver peut-être la profondeur de ces hachages.

Merci :)

Answer 1

Si vous avez juste besoin de savoir si un hachage est multidimensionnel, vous pouvez itérer sur ses valeurs et arrêter si une référence se trouve:

my $is_multi_dimensional = 0; 

for my $value (values %$hash_ref) { 
    if ('HASH' eq ref $value) { 
     $is_multi_dimensional = 1; 
     last; 
    } 
} 

ou vous pouvez utiliser la fonction each():

while (my (undef, $value) = each %$hash_ref) { 
    if ('HASH' eq ref $value) { 
     $is_multi_dimensional = 1; 
     last; 
    } 
} 

Answer 2

Vous pouvez essayer celui-ci pour connaître la profondeur de hachage Perl:

#!/usr/bin/perl 
use strict; 
my $hash_ref = { 

    'hashes' => { 
    'h1' => { 'klf' => '1', 'moomooland' => '1' }, 
    'h2' => { 'klf' => '2', 'moomooland' => '2' }, 
    'h3' => { 'klf' => '3', 'moomooland' => '3' } 
    }, 

    'keys' => { 
    'k1' => 'key1', 
    'k2' => 'key2', 
    'k3' => 'key3' 
    } 

}; 
print_nested_hash($hash_ref, 0); 

sub print_nested_hash { 
    my $hash_ref = shift; 
    my $depth = shift; 
    foreach my $key (sort keys %{$hash_ref}) { 
     print ' ' x $depth, $key, "\n"; 

     if (ref($hash_ref->{$key}) eq "HASH") { 
      print_nested_hash($hash_ref->{$key}, $depth+1); 
     } 
    } 
} 

SORTIE:

hashes 
    h1 
     klf 
     moomooland 
    h2 
     klf 
     moomooland 
    h3 
     klf 
     moomooland 
keys 
    k1 
    k2 
    k3 

Answer 3

Vous pouvez également first et grep pour cela:

use List::Util 'first'; 
say 'is multi-dimensional' if first { ref } values %$hash_ref; 

# explicitly check for HASH ref this time 
my $how_many_md_hashes = grep { 'HASH' eq ref } values %$hash_ref; 

NB. first (partie du module de base List::Util) courts-circuits est donc idéal pour les conditions et est probablement le plus rapide de toutes les options possibles.

/I3az/