Comment remplacer une clé de hachage Perl?

Question

Disons que si j'ai un hachage comme ceci:

$data = { 
    'key1' => { 
       'key2' => 'value1' 
       }, 
    'key3' => { 
       'key4' => { 
          'key5' => 'value2' 
          } 
       }, 
    }; 

Maintenant, comment puis-je remplacer la clé « key5 » avec un autre nom clé dire « key6 »? Je sais comment faire une boucle à travers le hachage & vider les valeurs, mais je ne sais pas comment remplacer les clés ou les valeurs en place. Merci de votre aide.

Answer 1

L'opérateur delete renvoie la valeur en cours de suppression. Donc ce

$data->{key3}{key4}{key6} = delete $data->{key3}{key4}{key5} 

fera ce que vous cherchez.

Answer 2

Vous ne pouvez pas le remplacer, mais vous pouvez faire une nouvelle clé facilement, puis delete() l'ancien:

$data->{key3}{key4}{key6} = $data->{key3}{key4}{key5}; 
delete $data->{key3}{key4}{key5}; 

Bien sûr, vous pouvez faire une sous-routine assez simple à faire. Cependant, ma première approche était fausse, et vous auriez besoin de faire une approche plus complexe qui passe dans la structure de données à modifier et l'élément à modifier, et étant donné que vous voulez des éléments à plusieurs niveaux, cela peut être difficile. Bien que si vous ne me dérange un peu fouillis:

sub hash_replace (\%$$) { 
    $_[0]->{$_[2]} = delete $_[0]->{$_[1]}; # thanks mobrule! 
} 

Ensuite, appelez-le:

hash_replace %{$data->{key3}{key4}}, "key5", "key6"; 

Ou la façon cool (Comment mieux dire que nous transformons « key5 » en « key6 » ?):

hash_replace %{$data->{key3}{key4}}, key5 => "key6"; 

(testé et fonctionne)

Answer 3

Ce 'fonctionne', mais est très codé en dur.

#!/bin/perl -w 
use strict; 

my $data = { 
    'key1' => { 
     'key2' => 'value1' 
    }, 
    'key3' => { 
     'key4' => { 
      'key5' => 'value2' 
     } 
    }, 
}; 

print "$data->{key3}->{key4}->{key5}\n"; 

my $save = $data->{key3}->{key4}->{key5}; 
delete $data->{key3}->{key4}->{key5}; 
$data->{key3}->{key4}->{key6} = $save; 

print "$data->{key3}->{key4}->{key6}\n"; 

Vous pouvez éliminer les - opérateurs entre les indices de hachage, mais pas celle d'après « $ data » « > » - comme dans la solution de Chris Lutz.

Answer 4

vous pouvez utiliser YAML pour plonger profondément dans votre hachage avec un simple regex:

use YAML::XS; 
my $yaml = Dump $hash; 
$yaml =~ s/key5/key6/; # may wish for global sub 
$hash = Load $yaml;