Existe-t-il une fonction standard Delphi pour échapper le HTML?

Question

J'ai un rapport censé prendre un contrôle de grille et produire une sortie HTML. Une des colonnes de la grille peut afficher un nombre de valeurs, ou <Any>. Quand ceci est sorti en HTML, bien sûr, il finit vide.

Je pourrais probablement écrire une routine pour utiliser StringReplace pour le transformer en <Any> afin qu'il affiche correctement ce cas particulier, mais je pense qu'il y en a probablement un dans la RTL qui a déjà été testé et qui fonctionne correctement. Quelqu'un sait où je pourrais le trouver?

Answer 1

Je suis sûr à 99% qu'une telle fonction n'existe pas dans le RTL (à partir de Delphi 2009). Bien sûr, cependant, il est trivial d'écrire une telle fonction.

Mise à jour

HTTPUtil.HTMLEscape est ce que vous recherchez:

function HTMLEscape(const Str: string): string; 

Je n'ose pas publier le code ici (violation du droit d'auteur, sans doute), mais la routine est très simple. Il code "<", ">", "&" et "" » à <, >, & et ". Il remplace également les caractères # 92, # 160 .. # 255 en décimal codes, par exemple \.

Cette dernière étape est inutile si le fichier est UTF-8, et également illogique, parce que les caractères spéciaux plus élevés, tels que ∮ sont laissées telles quelles, tandis que des caractères spéciaux inférieurs, tels que x, sont codés.

Mise à jour 2

En réponse à la réponse de Stijn Sanders, j'ai fait un simple test de performance.

program Project1; 

{$APPTYPE CONSOLE} 

uses 
    Windows, SysUtils; 

var 
    t1, t2, t3, t4: Int64; 
    i: Integer; 
    str: string; 
const 
    N = 100000; 


function HTMLEncode(const Data: string): string; 
var 
    i: Integer; 
begin 

    result := ''; 
    for i := 1 to length(Data) do 
    case Data[i] of 
     '<': result := result + '&lt;'; 
     '>': result := result + '&gt;'; 
     '&': result := result + '&amp;'; 
     '"': result := result + '&quot;'; 
    else 
     result := result + Data[i]; 
    end; 

end; 

function HTMLEncode2(Data: string):string; 
begin 
    Result:= 
    StringReplace(
    StringReplace(
    StringReplace(
    StringReplace(
     Data, 
     '&','&amp;',[rfReplaceAll]), 
     '<','&lt;',[rfReplaceAll]), 
     '>','&gt;',[rfReplaceAll]), 
     '"','&quot;',[rfReplaceAll]); 
end; 

begin 

    QueryPerformanceCounter(t1); 
    for i := 0 to N - 1 do 
    str := HTMLEncode('Testing. Is 3*4<3+4? Do you like "A & B"'); 
    QueryPerformanceCounter(t2); 

    QueryPerformanceCounter(t3); 
    for i := 0 to N - 1 do 
    str := HTMLEncode2('Testing. Is 3*4<3+4? Do you like "A & B"'); 
    QueryPerformanceCounter(t4); 

    Writeln(IntToStr(t2-t1)); 
    Writeln(IntToStr(t4-t3)); 

    Readln; 


end. 

La sortie est

532031 
801969 

Answer 2

J'utilise généralement ce code:

function HTMLEncode(Data:string):string; 
begin 
    Result:= 
    StringReplace(
    StringReplace(
    StringReplace(
    StringReplace(
    StringReplace(
     Data, 
     '&','&',[rfReplaceAll]), 
     '<','&lt;',[rfReplaceAll]), 
     '>','&gt;',[rfReplaceAll]), 
     '"','&quot;',[rfReplaceAll]), 
     #13#10,'<br />'#13#10,[rfReplaceAll]); 
end; 

(? Le droit d'auteur, il est open source)

Answer 3

Il semble ici est un petit concours :) Voici une implémentation supplémentaire:

function HTMLEncode3(const Data: string): string; 
var 
    iPos, i: Integer; 

    procedure Encode(const AStr: String); 
    begin 
    Move(AStr[1], result[iPos], Length(AStr) * SizeOf(Char)); 
    Inc(iPos, Length(AStr)); 
    end; 

begin 
    SetLength(result, Length(Data) * 6); 
    iPos := 1; 
    for i := 1 to length(Data) do 
    case Data[i] of 
     '<': Encode('&lt;'); 
     '>': Encode('&gt;'); 
     '&': Encode('&amp;'); 
     '"': Encode('&quot;'); 
    else 
     result[iPos] := Data[i]; 
     Inc(iPos); 
    end; 
    SetLength(result, iPos - 1); 
end; 

Mise à jour 1: Mis à jour initialement fourni un code incorrect.

Mise à jour 2: Et les temps:

HTMLEncode : 2286508597 
HTMLEncode2: 3577001647 
HTMLEncode3: 361039770 

Answer 4

HTTPApp de l'unité a une fonction appelée HTMLEncode. Il a aussi d'autres fonctions liées au HTML/HTTP.

Answer 5

que diriez-vous de cette façon de remplacer les caractères spéciaux:

function HtmlWeg(sS: String): String; 
var 
    ix,cc: Integer; 
    sC, sR: String; 
begin 
    result := sS; 
    ix := pos('\u00',sS); 

    while ix >0 do 
    begin 
    sc := copy(sS,ix+4,2) ; 
    cc := StrtoIntdef('$' +sC,32); 
    sR := '' + chr(cc); 
    sS := Stringreplace(sS, '\u00'+sC,sR,[rfreplaceall]) ; 
    ix := pos('\u00',sS); 
    end; 
    result := sS; 
end; 

Answer 6

Ma fonction combine la boucle for avec une nouvelle répartition minimale de la chaîne:

function HtmlEncode(const Value: string): string; 
var 
    i: Integer; 

begin 
    Result := Value; 
    i := 1; 

    while i <= Length(Result) do 
    begin 
    if Result[i] = '<' then 
    begin 
     Result[i] := '&'; 
     Insert('lt;', Result, i + 1); 
     Inc(i, 4); 
    end 
    else if Result[i] = '>' then 
    begin 
     Result[i] := '&'; 
     Insert('gt;', Result, i + 1); 
     Inc(i, 4); 
    end 
    else if Result[i] = '"' then 
    begin 
     Result[i] := '&'; 
     Insert('quot;', Result, i + 1); 
     Inc(i, 6); 
    end 
    else if Result[i] = '&' then 
    begin 
     Insert('amp;', Result, i + 1); 
     Inc(i, 5); 
    end 
    else 
     Inc(i); 
    end; 
end; 

Answer 7

Je ne sais pas dans quelle version delphi il a été introduit, mais il y a l'unité System.NetEncoding qui présente:

TNetEncoding.HTML.Encode 
TNetEncoding.HTML.Decode 

f onctions. Lire here. Vous n'avez plus besoin de bibliothèques externes pour cela.