cmake La commande add_custom_command ne fonctionne pas

Question

J'essaie de lancer gperf à partir d'un fichier cmake.

J'ai créé un très minime CMakeLists.txt ci-dessous.

Quand je cours par

$ cmake . 
$ make 

Il ne crée pas le fichier example.hpp

Ce qui pourrait être un problème avec le dessous CMakeLists.txt?

cmake_minimum_required(VERSION 2.6) 

function(gperf_generate_new source target) 

     add_custom_target(${target} echo "Creating ${target}") 

     add_custom_command(
       SOURCE ${source} 
       TARGET ${target} 
       COMMAND gperf -L c++ ${source} > ${target} 
       OUTPUTS ${target} 
       DEPENDS ${source} 
       ) 

endfunction() 

gperf_generate_new(command_options.new.gperf example.hpp) 

Answer 1

fichiers, produit par générateurs source-fichiers (comme gpref) sont rarement nécessaires en mode autonome. Au lieu de cela, ces fichiers sources sont généralement utilisés pour créer des exécutables ou des bibliothèques dans un projet.

Ainsi, le modèle standard de l'utilisation des générateurs de fichiers source dans le CMake ressemble:

# Call add_custom_command() with appropriate arguments for generate output file 
# Note, that *gperf* will work in the build tree, 
# so for file in the source tree full path should be used. 
function(gperf_generate_new input output) 
    add_custom_command(
     OUTPUT ${output} 
     COMMAND gperf -L c++ ${input} > ${output} 
     DEPENDS ${input} 
     COMMENT "Generate ${output}" # Just for nice message during build 
    ) 
endfunction() 

# Generate *example.hpp* file ... 
gperf_generate_new(${CMAKE_CURRENT_SOURCE_DIR}/command_options.new.gperf example.hpp) 

# ... for use it in executable 
add_executable(my_program ${CMAKE_CURRENT_BINARY_DIR}/example.hpp <other sources>) 

Si vous voulez seulement vérifier si example.hpp est la génération, au lieu de add_executable() utilisation

add_custom_target(my_target 
    ALL # Force target to be built with default build target. 
    DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/example.hpp 
) 

Remarque , cette liaison entre add_custom_command et add_custom_target est exprimée en utilisant le même nom de fichier dans leurs options OUTPUT et DEPENDS de manière correspondante. Avec un tel ordre de lien de ces commandes est insignifiant (mais les deux commandes doivent être appelées à partir du même script CMakeLists.txt).