Comment mettre à jour un expéditeur EmailAddress

Question

J'envoie des e-mails au nom d'un compte Shared MailBox - système générique? Comment puis-je mettre à jour l'expéditeur dans le courrier Outlook?

Je reçois une erreur d'exécution '438': Cet objet ne gère pas cette propriété ou méthode .De = "MYACCOUNT@ACCOUNT.com"

Function CreateEmail(MySQL As String) 
'On Error GoTo Exit_Function: 
Dim oOutlook As Outlook.Application 
Dim oEmailItem As MailItem 'rs As Recordset 

Dim rs As Recordset 
Set rs = CurrentDb.OpenRecordset(MySQL) 
If rs.RecordCount > 0 Then 
    rs.MoveFirst 
    Do Until rs.EOF 
    If IsNull(rs!standard_e_mail_addr) Then 
     rs.MoveNext 
    Else 
     If oOutlook Is Nothing Then 
      Set oOutlook = New Outlook.Application 
     End If 
     Set oEmailItem = oOutlook.CreateItem(olMailItem) 
     With oEmailItem 
      .To = rs!standard_e_mail_addr 
      .From = "MYACCOUNT@ACCOUNT.com" ' ** 
      .Subject = "Mandatory Action Required Submit In-Person Identification Form for " & rs!emp_fname 
      .Body = "EmpNo: " & rs!emp_no & vbCr & _ 
        "EmpName: " & rs!emp_fname & vbCr & _ 
        "DO NOT REPLY." 

      .Display 
      .Send 
      rs.Edit 
      rs!EmailNotification_Send = Date 
      rs.Update 

     End With 
     Set oEmailItem = Nothing 
     Set oOutlook = Nothing 
     rs.MoveNext 
End If 
Loop 

Else 
End If 
rs.Close 
Exit Function: 
    Exit Function 
End Function 

Answer 1

Bon, essayez: .SentOnBehalfOfName = """SenderName"" <MyAccount@Address.com>"

également en revue: Use another account for sender

Answer 2

tout d'abord, il n'y a pas besoin d'appeler Display avant d'appeler la méthode Send. Si vous avez configuré la boîte aux lettres partagée dans Outlook, vous devez utiliser la propriété SendUsingAccount qui permet de définir un objet Account représentant le compte sous lequel l'élément MailItem doit être envoyé. Par exemple:

Sub SendUsingAccount() 
    Dim oAccount As Outlook.account 
    For Each oAccount In Application.Session.Accounts 
    If oAccount.AccountType = olPop3 Then 
     Dim oMail As Outlook.MailItem 
     Set oMail = Application.CreateItem(olMailItem) 
     oMail.Subject = "Sent using POP3 Account" 
     oMail.Recipients.Add ("someone@example.com") 
     oMail.Recipients.ResolveAll 
     oMail.SendUsingAccount = oAccount 
     oMail.Send 
    End If 
    Next 
End Sub 

Utilisez SentOnBehalfOfName aussi longtemps que votre compte Exchange a l'autorisation SendAs pour la boîte aux lettres partagée ou d'un groupe de distribution, il sera envoyé à partir du compte partagé ou d'un groupe, pas envoyé au nom de.

With oEmailItem 
     .To = rs!standard_e_mail_addr 
     .SentOnBehalfOfName = "MYACCOUNT@ACCOUNT.com" 
     .Subject = "Mandatory Action Required Submit In-Person Identification Form for " & rs!emp_fname 
     .Body = "EmpNo: " & rs!emp_no & vbCr & _ 
       "EmpName: " & rs!emp_fname & vbCr & _ 
       "DO NOT REPLY." 
     .Send