Erreur d'exécution Microsoft VBScript Description de l'erreur: Objet requis: 'Serveur'

Question

Je tente d'exécuter un travail SQL quotidien qui envoie des messages à mon client à l'aide du serveur SMTP et des objets CDONT Mail. A déjà le code qui fonctionne bien pour moi. Récemment, j'ai mis à jour mon serveur de Microsoft Server 2003 à 2012 et SQL Server 2005 à 2014.

Ce code ci-dessous fonctionne très bien dans Classic ASP dans le serveur. Mais dans l'emploi sql obtenir erreur

Set objEMail = Server.CreateObject("CDO.Message") 
Set objConfig = Server.CreateObject("CDO.Configuration") 
Set Confi = objConfig.Fields 
Confi("http://schemas.microsoft.com/cdo/configuration/sendusing") = 1 
Confi("http://schemas.microsoft.com/cdo/configuration/smtpserverpickupdirectory") = "C:\inetpub\mailroot\pickup" 
Confi.Update 
Set objEMail.Configuration = objConfig 
objEMail.To = "hi@xx.in" 
objEMail.From ="hello@yy.com" 
objEMail.Subject = "Email subject goes here" 
objEMail.HTMLBody = "Hi Sql job data" 
objEMail.Send 
Set objEMail = Nothing 

Exécuté en tant qu'utilisateur: service NT \ SQLSERVERAGENT. Code d'erreur: 0 Erreur Source = erreur d'exécution Microsoft VBScript Description de l'erreur: Objet requis: 'Serveur' #

Answer 1

Server est un objet spécifique à ASP Classic.

Votre code est probablement exécuté par Windows Script Host (wscript.exe/cscript.exe), qui possède sa propre fonction CreateObject.

Retirez simplement le Server. pour le faire fonctionner.

Set objEMail = CreateObject("CDO.Message") 
Set objConfig = CreateObject("CDO.Configuration") 

Set Confi = objConfig.Fields 
Confi("http://schemas.microsoft.com/cdo/configuration/sendusing") = 1 
Confi("http://schemas.microsoft.com/cdo/configuration/smtpserverpickupdirectory") = "C:\inetpub\mailroot\pickup" 
Confi.Update 

Set objEMail.Configuration = objConfig 
objEMail.To = "hi@xx.in" 
objEMail.From ="hello@yy.com" 
objEMail.Subject = "Email subject goes here" 
objEMail.HTMLBody = "Hi Sql job data" 
objEMail.Send 

Set objEMail = Nothing 

Pour mémoire, l'option est Server en ASP classique, ainsi, le code ci-dessus fonctionnerait dans les deux environnements.