Comment puis-je modifier un descripteur d'attribut Moose?

Question

Après phaylon's answer to "How can I flexibly add data to Moose objects?", supposons que je l'attribut Moose suivante:

has custom_fields => (
    traits  => [qw(Hash)], 
    isa  => 'HashRef', 
    builder => '_build_custom_fields', 
    handles => { 
     custom_field   => 'accessor', 
     has_custom_field  => 'exists', 
     custom_fields  => 'keys', 
     has_custom_fields => 'count', 
     delete_custom_field => 'delete', 
    }, 
); 

sub _build_custom_fields { {} } 

Maintenant, supposons que je voudrais croasser si vous essayez de lire (mais pas écrire) à un champ personnalisé non existant. J'ai été suggéré par phaylon pour envelopper custom_field avec un modificateur autour. J'ai expérimenté avec les modificateurs around en suivant les divers exemples dans les docs de Moose, mais je n'ai pas pu comprendre comment modifier un handle (plutôt qu'une simple méthode d'objet).

D'autre part, existe-t-il une autre façon d'implémenter cette clé croak-if-try-to-read-nonexisting-key?

Answer 1

Ce ne sont encore que des méthodes générées par Moose. Vous pouvez juste faire:

around 'custom_field' => sub { 
    my $orig = shift; 
    my $self = shift; 
    my $field = shift; 

    confess "No $field" unless @_ or $self->has_custom_field($field); 

    $self->$orig($field, @_); 
}; 

(.. croak est pas très utile dans les modificateurs de méthode au moment où il va simplement vous indiquer au code de Moose interne)

En fait, vous n'avez pas besoin d'utiliser around pour cela. L'utilisation de before est plus simple:

before 'custom_field' => sub { 
    my $self = shift; 
    my $field = shift; 

    confess "No $field" unless @_ or $self->has_custom_field($field); 
};