Comment ajouter un numéro d'incrémentation automatique à un tableau?

Question

Je lis le contenu du fichier en Perl par le code suivant

my @files = glob("$PATH/*"); 
foreach my $file (@files){ 
    open(MYFILE,"<$file"); 
    my @fileContent = <MYFILE>; 
    close(MYFILE); 
} 

Maintenant, je veux préfixer numéro auto-incrémentée à chaque ligne. Quelque chose comme -

fileContent[0] = 1: This 
fileContent[1] = 2: is 
fileContent[2] = 3: a 
fileContent[3] = 4: text 
fileContent[4] = 5: file. 

Quelqu'un sait un moyen efficace de le faire?

Merci!

Answer 1

Que diriez-vous d'un one-liner?

perl -wne 'print "$.: $_"; close ARGV if eof;' path/* 

ou à l'intérieur d'un script, avec un tableau:

use strict; 
use warnings; 
use autodie; 

while (<tmp/data*>) { 
    open my $fh, '<', $_; 
    my @fileContent; 
    push @fileContent, "$.: $_" while <$fh>; 
} 

Documentation sur $.here.

Answer 2

Essayez ceci pour votre ligne d'affectation:

my $i; 
my @fileContent = map{++$i.": $_"} (<MYFILE>) 

Answer 3

efficace? Je ne sais pas qu'il y a vraiment un inefficace façon de le faire (sauf si vous le rendre inefficace exprès).

for my $lineNumber (1..@fileContent) { 
    substr($fileContent[$lineNumber-1], 0, 0, "$lineNumber: "); 
} 

Answer 4

Voici votre code, sous la direction d'utiliser des variables lexicales, 3 arg ouvertes, et une déclaration de carte pour ajouter les numéros de ligne.

my @files = glob("$PATH/*"); 
foreach my $file (@files){ 
    open my $fh,'<', $file or die $!; 
    my $i = 1; 
    my @fileContent = map {$i++.": $_"} <$fh>; 

    # do something with @fileContent 
} 

Voici un exemple qui est un peu plus perlienne (en utilisant plus des fonctions automatiques):

for (<$PATH/*>) { 
    local @ARGV = $_; 
    my $i = 1; 
    my @lines = map {$i++.": $_"} <>; 

    # do something with @lines 
} 

Et voici un exemple qui utilise $. (la ligne d'entrée numérique) et une boucle while pour lire le fichier ligne par ligne.

for (<$PATH/*>) { 
    local (@ARGV, $_) = $_; 
    my @lines; 
    push @lines, "$.: $_" while <>; 

    # do something with @lines 
} 

Answer 5

Changer votre ouverture à:

open MYFILE, '-|', 'grep', '-n', '', $file