coldfusion trouver une structure dans un tableau

Question

J'ai un objet qui contient un tableau de structures, le code qui le génère boucle sur une requête, prend différentes valeurs de chaque ligne de la requête et remplit une structure, quand la ligne est terminée il ajoute à un tableau et le processus recommence:

<cfscript> 
    variables.x = 1; 
    variables.aArray = []; 
    // loop over my query 
    while(variables.x lte variables.qQuery.recordcount){ 
     variables.stStruct   = {}; 
     variables.stStruct.nID  = variables.qQuery.id[variables.x]; 
     variables.stStruct.sText = variables.qQuery.text[variables.x]; 

     //etc... 

     arrayAppend(variables.aArray,variables.stStruct); 
     variables.x++; 
    } 
    variables.oObject.setArray(variables.aArray); 
</cfscript> 

plus tard dans mon code, je veux être en mesure de tirer les détails sur les éléments de ce tableau avec seulement les JNV à titre indicatif. Je ne connais pas la position du tableau de ce nID, ce qui signifie utiliser une méthode convulatoire pour essayer de le trouver.

J'ai eu l'idée de créer une structure de positions à côté de lui en modifiant le code ci-dessus avec.

<cfscript> 
    variables.x = 1; 
    variables.aArray = []; 
    variables.stTracker = {}; 

    while...yadda 
     variables.stStruct = {}; 
     yadda yadda 

     structInsert(variables.stTracker,"variables.qQuery.id[variables.x]","variables.x"); 
     variables.x++; 

    while end 

    variables.oObject.setArray(variables.aArray); 
    variables.oObject.setTracker(variables.stTracker); 
</cfscript> 

Ce qui signifierait alors que je pouvais faire quelque chose comme variables.nPosition = structFindKey(variables.oObject.getTracker(),'88')[1].value;. Cela semble toujours assez inélégant et je me demande s'il me manque quelque chose qui rend cela beaucoup plus facile que ce que je fais.

Je serais très heureux s'il y avait une solution utilisant Java pour résoudre ce problème.

Answer 1

Au lieu de construire un tableau de structures à partir d'une requête existante, je recommande d'effectuer un Query of Queries. Il vous permettra d'utiliser des instructions SQL pour interroger votre jeu de résultats existant en mémoire. Cela suppose que toutes les données dont vous avez besoin sont déjà disponibles dans la requête existante (cela ressemble à votre question).

Un exemple de requête requête serait:

<cfquery dbtype="query" name="qoqexample"> 
    SELECT id, text, other_columns 
    FROM variables.qQuery 
    WHERE id = <cfqueryparam cfsqltype="cf_sql_integer" value="#nID#"> 
</cfquery> 

Answer 2

Vous pouvez utiliser Java LinkedHashMap qui fonctionne comme un struct, mais maintiendra l'ordre dans lequel les éléments ont été ajoutés. Cela signifie que vous n'avez pas besoin d'utiliser un tableau du tout (il n'est pas certain que ce sera un problème pour vous)

Vous pourrez utiliser toutes vos fonctions natives CF sur cet objet comme vous le feriez pour une structure normale.

var container = createObject("java", "java.util.LinkedHashMap").init(); 
for (var x = 1; x <= qQuery.recordCount; x++) { 
    container[qQuery['nid'][x]] = qQuery['stext'][x]; 
} 

test pour une clé comme d'habitude:

structKeyExists(container, '123'); 

http://docs.oracle.com/javase/6/docs/api/java/util/LinkedHashMap.html

L'autre option, je crois que vous avez envisagé est une carte du nid à la position d'index de tableau ici keys:

var keys = {}; 
var container = []; 
for (var x = 1; x <= qQuery.recordCount; x++) { 
    var item = {}; 
    item[qQuery['nid'][x]] = qQuery['stext'][x]; 

    container[x] = item; 
    keys[qQuery['nid'][x]] = x; 
} 

Answer 3

CFLib.org semble avoir une probabilité candidat: arrayOfStructsFind

<cfscript> 
/** 
* Returns the position of an element in an array of structures. 
* 
* @param array  Array to search. (Required) 
* @param searchKey  Key to check in the structs. (Required) 
* @param value  Value to search for. (Required) 
* @return Returns the numeric index of a match. 
* @author Nath Arduini (nathbot@gmail.com) 
* @version 0, June 11, 2009 
*/ 
function arrayOfStructsFind(Array, SearchKey, Value){ 
    var result = 0; 
    var i = 1; 
    var key = ""; 
    for (i=1;i lte arrayLen(array);i=i+1){ 
     for (key in array[i]) 
     { 
      if(array[i][key]==Value and key == SearchKey){ 
       result = i; 
       return result; 
      } 
     } 
    } 

    return result; 
} 
</cfscript> 

Ainsi, dans votre cas, vous l'utiliser comme:

ArrayOfStructsFind(variables.oObject.getArray(),"nID","12345")