Deux tableaux croisés dynamiques dans la même feuille Excel

Question

J'ai créé une table croisée dynamique dans la même feuille avec les données source. Maintenant, je veux créer un deuxième tableau croisé dynamique dans la même feuille avec la même source de données, mais avec différentes données imprimées dans le tableau croisé dynamique (bien sûr). Je continue d'obtenir une erreur, car il est dit que Table Pivot ne peut pas remplacer une autre table de Pivot. Cependant, ils ont choisi les plages où les tableaux croisés dynamiques sont créés, ils ne se remplacent pas les uns les autres. J'ai testé manuellement aussi. De plus, si j'enregistre le processus, il utilise simplement les références exactes pour les données sources, que je ne veux pas utiliser parce que le lastrow et la lastcolumn changent tous les jours. Juste pour le rappeler, la macro fonctionne très bien pour créer la première table. La deuxième table est le problème. Ci-dessous, je vais fournir mon code tel qu'il est maintenant.

Dim DSheet As Worksheet 
Dim PCache As PivotCache 
Dim PTable1 As PivotTable 
Dim PTable2 As PivotTable 
Dim PRange As Range 

Application.DisplayAlerts = True 
Set DSheet = Worksheets("Budget_Report") 

Set PRange = DSheet.Range(Cells(1, 53), Cells.SpecialCells(xlCellTypeLastCell)) 

Set PCache = ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:=PRange) 
Set PTable1 = PCache.CreatePivotTable(TableDestination:=DSheet.Cells(4, 1), TableName:="PivotTable1") 
Set PTable2 = PCache.CreatePivotTable(TableDestination:=DSheet.Cells(17, 2), TableName:="PivotTable2") 

With ActiveSheet.PivotTables("PivotTable1") 

    With .PivotFields("T-Lane") 
    .Orientation = xlRowField 
    .Position = 1 
    .Subtotals(1) = True 
    .Subtotals(1) = False 
    End With 

    With .PivotFields("Monthly Cost FCST") 
    .Orientation = xlDataField 
    .Position = 1 
    .Function = xlAverage 
    .Caption = "Monthly Cost Forecast" 
    End With 

End With 

With ActiveSheet.PivotTables("PivotTable2") 

    With .PivotFields("Oran") 
    .Orientation = xlRowField 
    .Position = 1 
    .Subtotals(1) = True 
    .Subtotals(1) = False 
    End With 

    With .PivotFields("Monthly Cost FCST") 
    .Orientation = xlDataField 
    .Position = 1 
    .Function = xlAverage 
    .Caption = "Monthly Cost Forecast" 
    End With 

End With 

Answer 1

Lors de l'insertion de la première table de pivotement et d'insérer une autre avant remplissage de la première, la plage de la table de pivotement vide de la première table de pivot occupe la cellule de destination [de DSheet.Cells (17, 2)] de la deuxième pivot.

Je pense que vous devriez insérer le premier tableau croisé dynamique et le remplir, puis en insérer un autre et le remplir aussi.

Voir si cela résout votre problème.

Dim DSheet As Worksheet 
Dim PCache As PivotCache 
Dim PTable1 As PivotTable 
Dim PTable2 As PivotTable 
Dim PRange As Range 

Application.DisplayAlerts = True 
Set DSheet = Worksheets("Budget_Report") 

Set PRange = DSheet.Range(Cells(1, 53), Cells.SpecialCells(xlCellTypeLastCell)) 

Set PCache = ActiveWorkbook.PivotCaches.Create(SourceType:=xlDatabase, SourceData:=PRange) 
Set PTable1 = PCache.CreatePivotTable(TableDestination:=DSheet.Cells(4, 1), TableName:="PivotTable1") 

With ActiveSheet.PivotTables("PivotTable1") 

    With .PivotFields("T-Lane") 
    .Orientation = xlRowField 
    .Position = 1 
    .Subtotals(1) = True 
    .Subtotals(1) = False 
    End With 

    With .PivotFields("Monthly Cost FCST") 
    .Orientation = xlDataField 
    .Position = 1 
    .Function = xlAverage 
    .Caption = "Monthly Cost Forecast" 
    End With 

End With 

Set PTable2 = PCache.CreatePivotTable(TableDestination:=DSheet.Cells(17, 2), TableName:="PivotTable2") 

With ActiveSheet.PivotTables("PivotTable2") 

    With .PivotFields("Oran") 
    .Orientation = xlRowField 
    .Position = 1 
    .Subtotals(1) = True 
    .Subtotals(1) = False 
    End With 

    With .PivotFields("Monthly Cost FCST") 
    .Orientation = xlDataField 
    .Position = 1 
    .Function = xlAverage 
    .Caption = "Monthly Cost Forecast" 
    End With 

End With 

Answer 2

De l'MSDN doc on pivot tables:

"Important" Si vous définissez les tableaux croisés dynamiques multiples sur la feuille de calcul Excel , il est possible les tables résultantes peuvent croître et se chevauchent les uns des autres si l'activité renvoie un grand ensemble de données. Dans ce scénario, vous recevrez "Un rapport de tableau croisé dynamique ne peut pas chevaucher un autre rapport de tableau croisé dynamique " lorsque vous actualisez les données. Vous pouvez corriger cette erreur en ajoutant des colonnes ou des lignes supplémentaires entre les tables pivotantes à pour permettre aux tables de se développer sans chevauchement.