Comment affecter un résultat exec à une variable sql?

Question

Comment affectez-vous le résultat d'un appel exec à une variable dans SQL? J'ai un proc stocké appelé up_GetBusinessDay, qui renvoie une seule date.

Pouvez-vous faire quelque chose comme ceci:

exec @PreviousBusinessDay = dbo.up_GetBusinessDay @Date, -1 

Answer 1

J'utilise toujours la valeur de retour pour renvoyer l'état d'erreur. Si vous devez renvoyer une valeur, j'utiliserais un paramètre de sortie.

échantillon

procédure stockée, avec un paramètre de SORTIE:

CREATE PROCEDURE YourStoredProcedure 
(
    @Param1 int 
    ,@Param2 varchar(5) 
    ,@Param3 datetime OUTPUT 
) 
AS 
IF ISNULL(@Param1,0)>5 
BEGIN 
    SET @Param3=GETDATE() 
END 
ELSE 
BEGIN 
    SET @Param3='1/1/2010' 
END 
RETURN 0 
GO 

appel à la procédure stockée, avec un paramètre de SORTIE:

DECLARE @OutputParameter datetime 
     ,@ReturnValue  int 

EXEC @ReturnValue=YourStoredProcedure 1,null, @OutputParameter OUTPUT 
PRINT @ReturnValue 
PRINT CONVERT(char(23),@OutputParameter ,121) 

SORTIE:

0 
2010-01-01 00:00:00.000 

Answer 2

De l'documentation (en supposant que vous utilisez SQL Server):

USE AdventureWorks; 
GO 
DECLARE @returnstatus nvarchar(15); 
SET @returnstatus = NULL; 
EXEC @returnstatus = dbo.ufnGetSalesOrderStatusText @Status = 2; 
PRINT @returnstatus; 
GO 

Alors oui, il devrait fonctionner de cette façon.

Answer 3

Cela fonctionne si vous souhaitez simplement renvoyer un nombre entier:

DECLARE @ResultForPos INT 
EXEC @ResultForPos = storedprocedureName 'InputParameter' 
SELECT @ResultForPos 

Answer 4

declare @EventId int 

CREATE TABLE #EventId (EventId int) 

insert into #EventId exec rptInputEventId 

set @EventId = (select * from #EventId) 

drop table #EventId