Comment convertir des secondes en HH: MM: SS en utilisant T-SQL

Question

La situation est que vous avez une valeur en secondes (XXX.XX), et vous voulez convertir en HH: MM: SS en utilisant T-SQL.

Exemple:

• 121,25 s devient 00: 02: 01,25

Answer 1

Vous voulez multiplier en millisecondes lorsque la partie fractionnaire est rejetée.

SELECT DATEADD(ms, 121.25 * 1000, 0) 

Si vous voulez sans la partie de date, vous pouvez utiliser convert, avec un style 114

SELECT CONVERT(varchar, DATEADD(ms, 121.25 * 1000, 0), 114) 

Answer 2

En utilisant SQL Server 05 je peux obtenir ce travail en utilisant:

declare @OrigValue int; 
set @OrigValue = 121.25; 
select replace(str(@OrigValue/3600,len(ltrim(@OrigValue/3600))+abs(sign(@OrigValue/359999)-1)) + ':' + str((@OrigValue/60)%60,2) + ':' + str(@OrigValue%60,2),' ','0') 

Answer 3

Si le montant de votre temps dépasse 24 heures il ne sera pas traitée correctement avec le DATEADD et Méthodes CONVERT.

SELECT CONVERT(varchar, DATEADD(ms, 24*60*60 * 1000, 0), 114) 
00:00:00:000 

La fonction suivante prendra en charge les durées supérieures à 24 heures (~ max 35,791,394 heures).

create function [dbo].[ConvertTimeToHHMMSS] 
(
    @time decimal(28,3), 
    @unit varchar(20) 
) 
returns varchar(20) 
as 
begin 

    declare @seconds decimal(18,3), @minutes int, @hours int; 

    if(@unit = 'hour' or @unit = 'hh') 
     set @seconds = @time * 60 * 60; 
    else if(@unit = 'minute' or @unit = 'mi' or @unit = 'n') 
     set @seconds = @time * 60; 
    else if(@unit = 'second' or @unit = 'ss' or @unit = 's') 
     set @seconds = @time; 
    else set @seconds = 0; -- unknown time units 

    set @hours = convert(int, @seconds /60/60); 
    set @minutes = convert(int, (@seconds/60) - (@hours * 60)); 
    set @seconds = @seconds % 60; 

    return 
     convert(varchar(9), convert(int, @hours)) + ':' + 
     right('00' + convert(varchar(2), convert(int, @minutes)), 2) + ':' + 
     right('00' + convert(varchar(6), @seconds), 6) 

end 

Utilisation:

select dbo.ConvertTimeToHHMMSS(123, 's') 
select dbo.ConvertTimeToHHMMSS(96.999, 'mi') 
select dbo.ConvertTimeToHHMMSS(35791394.999, 'hh') 
0:02:03.000 
1:36:59.940 
35791394:59:56.400 

Answer 4

secondes Convertir les heures requête de sélection:

SELECT field_in_seconds,round((field_in_seconds/3600),2) FROM a_table;

Cela vous donnera le résultat au format décimal. Je ne sais pas comment convertir 1.50 à 1:30. S'il vous plaît, n'hésitez pas à modifier mon code!

Answer 5

SELECT substring(convert (varchar(23),Dateadd(s,10000,LEFT(getdate(),11)),121),12,8) 

10000 est votre valeur en sec

Answer 6

DECLARE @seconds AS int = 896434; 
SELECT 
    CONVERT(varchar, (@seconds/86400))    --Days 
    + ':' + 
    CONVERT(varchar, DATEADD(ss, @seconds, 0), 108); --Hours, Minutes, Seconds 

Sorties:

10:09:00:34 

Answer 7

Pour les questions ayant à l'utilisation DATEADD et CONVERT pendant quelques secondes de plus de 24 heures, nous pouvons utiliser le module pour obtenir autour de cela:

SELECT CONVERT(varchar, @seconds/86400) + ':' + -- Days 
CONVERT(varchar, DATEADD(ms, (@seconds % 86400) * 1000, 0), 114) 
as "Converted to D:HH:MM:SS.MS" 

Answer 8

DECLARE @TimeinSecond INT 
SET @TimeinSecond = 340 -- Change the seconds 
SELECT RIGHT('0' + CAST(@TimeinSecond/3600 AS VARCHAR),2) + ':' + 
RIGHT('0' + CAST((@TimeinSecond/60) % 60 AS VARCHAR),2) + ':' + 
RIGHT('0' + CAST(@TimeinSecond % 60 AS VARCHAR),2) 

Answer 9

C'est ce que je l'utilise (généralement pour les rapports de courrier électronique de table html)

declare @time int, @hms varchar(20) 
set @time = 12345 
set @hms = cast(cast((@Time)/3600 as int) as varchar(3)) 
    +':'+ right('0'+ cast(cast(((@Time)%3600)/60 as int) as varchar(2)),2) 
    +':'+ right('0'+ cast(((@Time)%3600)%60 as varchar(2)),2) +' (hh:mm:ss)' 
select @hms 

Answer 10

En utilisant SQL Server 2008

declare @Seconds as int = 3600; 
SELECT CONVERT(time(0), DATEADD(SECOND, @Seconds, 0)) as 'hh:mm:ss' 

Answer 11

DECLARE @Seconds INT = 86200; 
SELECT 
CONVERT(VARCHAR(15), 
CAST(CONVERT(VARCHAR(12), @Seconds/60/60 % 24) 
+':'+ CONVERT(VARCHAR(2), @Seconds/60 % 60) 
+':'+ CONVERT(VARCHAR(2), @Seconds % 60) AS TIME), 100) AS [HH:MM:SS (AM/PM)]