Delphi 7: comment exécuter la commande shell et vérifier le résultat?

Question

J'utilise Delphi 7 et ne peux pas prédire la version cible de Windows.

J'ai besoin de créer une base de données (probablement MySQL, mais peut-être quelque chose d'autre) et de définir certaines structures de table. Je n'ai pas besoin de renseigner des données. Malheureusement, tous les composants ADO semblent s'attendre à ce qu'une base de données existe déjà et ils vous permettront alors de la manipuler. Donc, comme il ne s'agit que de quelques commandes simples, j'ai pensé que je pourrais aussi bien utiliser ShellExectute().

D'accord? Être en désaccord?

Quelqu'un peut-il me donner un exemple de code qui va tenter de lancer "MySql --version" et me laisser vérifier le résultat? Après cela, je devrais être capable de le comprendre par moi-même. Merci.

---

[modifier]

Aucune infraction prévu, mais je ne sais comment google. C'est juste que je ne trouve pas de résultats utiles. C'est ma propre faute de ne pas être explicite dans cette question, alors s'il vous plaît accepter mes excuses - ce dont j'ai besoin est un exemple de code, pas seulement le nom d'un composant.

Désolé (et merci pour les réponses à ce jour (qui sont tous +1))

---

[modifier]

Les liens que Robert donne faire le travail (procédure RunDosInMemo() ne l'astuce) ... MAIS Vous devez vous rappeler d'inclure une extension .exe (donc, 'notepad.exe', pas seulement 'notepad', et de ge un chemin complet si votre commande n'est pas sur le chemin.)

Answer 1

Voici un article qui explique en détail

Capture the output from a DOS (command/console) Window

Mais bref, vous devez créer deux tuyaux pour lire et écrire la sortie. Vous devez ensuite définir StdInput et StdOutput dans le TStartUpInfo structure, puis passer cette structure à l'appel CreateProcess().

Voici another article qui indique comment attendre la fin du processus.

Answer 2

Je me demande pourquoi tout le monde qui veut lancer un nouveau processus te nds pour utiliser ShellExecute à la place, qui est conçu pour ouvrir le fichier dans l'application associée?

Vous voulez un nouveau processus? Ensuite, utilisez CreateProcess. Fin de l'histoire. CreateProcess vous permet d'attendre le processus, d'obtenir son code de sortie, de lire sa sortie de la console et bien d'autres.

Answer 3

Ce que vous cherchez, probablement, est une base de données intégrée.Certaines options:

• Firebird Embarqués
• embarqué MySQL
• SQLite

Avec l'une des bases de données et des composants d'accès aux données appropriées (pas sûr à propos de ADO pour FB intégré et MySQL), vous sera en mesure de:

• attach sans DB
• créer un DB
• puis créer les tables

Answer 4

Utilisation DSiExecuteAndCapture de DSiWin32:

var 
    exitCode: integer; 
    output : TStringList; 
begin 
    output := TStringList.Create; 
    try 
    if DSiExecuteAndCapture('mysql --version', output, '', exitCode) = 0 then 
     Log(Format('error %d, cannot start', [GetLastError])) 
    else begin 
     // check exitCode and output 
    end; 
    finally FreeAndNil(output); end; 
end; 

Answer 5

J'ai sauvé ce d'un newsgroup message il y a longtemps; Je ne sais pas qui est originallall l'a écrit, cependant.

Ce code vous permet d'exécuter une application DOS et de capturer sa sortie dans un TMemo. Vous pouvez ensuite tirer ce que vous avez besoin du mémo avec un peu d'essais et d'erreurs d'analyse des lignes.

procedure TFMainForm.RunDosInMemo(const DosApp: String; AMemo: TRichEdit); 
const 
    ReadBuffer = 2400; 
var 
    Security : TSecurityAttributes; 
    StdInPipeR, StdInPipeW : THandle; 
    StdOutPipeR, StdOutPipeW : THandle; 
    StartInfo : TStartUpInfo; 
    ProcessInfo : TProcessInformation; 
    Buffer : PByte; 
    BytesAvailable, BytesRead : DWord; 
    sDosApp: String; 
    sData: RawByteString; 
begin 
    sDosApp := DosApp; 
    UniqueString(sDosApp); 

    with Security do begin 
    nLength := SizeOf(TSecurityAttributes); 
    bInheritHandle := True; 
    lpSecurityDescriptor := nil; 
    end; 

    if CreatePipe(StdInPipeR, StdInPipeW, @Security, 0) then 
    try 

    SetHandleInformation(StdInPipeW, HANDLE_FLAG_INHERIT, 0); 
    if CreatePipe(StdOutPipeR, StdOutPipeW, @Security, 0) then 
    try 
     SetHandleInformation(StdOutPipeR, HANDLE_FLAG_INHERIT, 0); 
     GetMem(Buffer, ReadBuffer); 
     try 
     ZeroMemory(@StartInfo, SizeOf(StartInfo)); 
     StartInfo.cb := SizeOf(StartInfo); 
     StartInfo.hStdOutput := StdOutPipeW; 
     StartInfo.hStdInput := StdInPipeR; 
     StartInfo.dwFlags := STARTF_USESTDHANDLES or STARTF_USESHOWWINDOW; 
     StartInfo.wShowWindow := SW_HIDE; 

     if CreateProcess(nil, 
         PChar(sDosApp), 
         nil, 
         nil, 
         True, 
         NORMAL_PRIORITY_CLASS, 
         nil, 
         nil, 
         StartInfo, 
         ProcessInfo) then 
      try 
      while WaitForSingleObject(ProcessInfo.hProcess, 500) <> WAIT_TIMEOUT do 
       Application.ProcessMessages; 
      while PeekNamedPipe(StdOutPipeR, nil, 0, nil, BytesAvailable, nil) do 
      begin 
       if BytesAvailable < 1 then 
       Break; 
       if BytesAvailable > ReadBuffer then 
       BytesAvailable := ReadBuffer; 
       if not ReadFile(StdOutPipeR, 
           Buffer[0], 
           BytesAvailable, 
           BytesRead, 
           nil) then 
       Break; 
       SetString(sData, PAnsiChar(Buffer), BytesRead); 
       // assign an appropriate codepage for the output data: 
       // 0 for default Ansi, 1252 or 20157 for ASCII, 1200 for 
       // Unicode, etc... 
       SetCodePage(sData, ...); 
       // this is faster and more efficient than reading/writing the 
       // Text property directly... 
       AMemo.SelStart := AMemo.GetTextLen; 
       AMemo.SelLength := 0; 
       AMemo.SelText := sData; 
      end; 
      finally 
      CloseHandle(ProcessInfo.hThread); 
      CloseHandle(ProcessInfo.hProcess); 
      end; 
     finally 
     FreeMem(Buffer); 
     end; 
    finally 
     CloseHandle(StdOutPipeR); 
     CloseHandle(StdOutPipeW); 
    end; 
    finally 
    CloseHandle(StdInPipeR); 
    CloseHandle(StdInPipeW); 
    end; 
end; 

Answer 6

j'ai écrit une unité et un ensemble de composants pour gérer la redirection de console dans delphi tout à fait il y a longtemps:

http://www.fulgan.com/delphi/dospipes15.zip

Mais au-delà, vous ne devriez pas avoir à passer par ce qui suit: utilisez le composant de connexion ADO simplement pour vous connecter au catalogue par défaut de la base de données, puis utilisez la méthode "execute" pour créer la base de données et le schéma dont vous avez besoin. La base de données SERVER doit être correctement installée et exécutée pour que cela fonctionne, mais, au moins avec MSSQL, il n'y a aucun problème avec la création de nouvelles bases de données de cette façon. Cependant, la chaîne de connexion exacte à utiliser peut varier en fonction de la base de données cible.