Comment puis-je obtenir une liste de tous les fichiers avec une certaine extension d'un répertoire spécifique?

Question

J'utilise ce code pour obtenir une liste de tous les fichiers dans un répertoire spécifique:

opendir DIR, $dir or die "cannot open dir $dir: $!"; 
my @files= readdir DIR; 
closedir DIR; 

Comment puis-je modifier ce code ou d'ajouter quelque chose à afin qu'il ne recherche que les fichiers texte et charge uniquement le tableau avec le préfixe du nom de fichier?

contenu du répertoire Exemple:

. 
.. 
923847.txt 
98398523.txt 
198.txt 
deisi.jpg 
oisoifs.gif 
lksdjl.exe 

Exemple contenu du tableau:

files[0]=923847 
files[1]=98398523 
files[2]=198 

Answer 1

my @files = glob "$dir/*.txt"; 
for (0..$#files){ 
    $files[$_] =~ s/\.txt$//; 
} 

Answer 2

il suffit de changer une ligne:

my @files= map{s/\.[^.]+$//;$_}grep {/\.txt$/} readdir DIR; 

Answer 3

Pour Parvenez ». fichiers txt ", vous pouvez utiliser un test de fichier oper ator (-f: fichier normal) et une regex.

my @files = grep { -f && /\.txt$/ } readdir $dir; 

Sinon, vous pouvez chercher seulement des fichiers texte, en utilisant -T de Perl (opérateur de test de fichier ascii-texte)

my @files = grep { -T } readdir $dir; 

Answer 4

Si vous pouvez utiliser les nouvelles fonctionnalités de Perl 5.10, voici comment Je l'écrirais.

use strict; 
use warnings; 
use 5.10.1; 
use autodie; # don't need to check the output of opendir now 

my $dir = "."; 

{ 
    opendir my($dirhandle), $dir; 
    for(readdir $dirhandle){ # sets $_ 
    when(-d $_){ next } # skip directories 
    when(/^[.]/){ next } # skip dot-files 

    when(/(.+)[.]txt$/){ say "text file: ", $1 } 
    default{ 
     say "other file: ", $_; 
    } 
    } 
    # $dirhandle is automatically closed here 
} 

Ou si vous avez des répertoires très grand, vous pouvez utiliser une boucle while.

{ 
    opendir my($dirhandle), $dir; 
    while(my $elem = readdir $dirhandle){ 
    given($elem){ # sets $_ 
     when(-d $_){ next } # skip directories 
     when(/^[.]/){ next } # skip dot-files 

     when(/(.+)[.]txt$/){ say "text file: ", $1 } 
     default{ 
     say "other file: ", $_; 
     } 
    } 
    } 
} 

Answer 5

Il suffit d'utiliser ceci:

my @files = map {-f && s{\.txt\z}{} ? $_ :()} readdir DIR; 

Answer 6

C'est la façon la plus simple que j'ai trouvé (comme lisible par l'homme) en utilisant la fonction glob:

# Store only TXT-files in the @files array using glob 
my @files = grep (-f ,<*.txt>); 
# Write them out 
foreach $file (@files) { 
    print "$file\n"; 
} 

De plus, le « -f "garantit que seuls les fichiers réels (et non les répertoires) sont stockés dans le tableau.