Comment obtenir la date du samedi (ou n'importe quel autre jour de la semaine) - SQL Server

Question

Comment obtenir la date du samedi. J'ai rendez-vous aujourd'hui avec moi.

GETDATE() 

Comment faire.

Par exemple. AUJOURD'HUI est 08-08-2011

Je veux que la sortie 08-13-2011

Answer 1

Ceci est une fonction qui sera de retour le samedi suivant si vous l'appelez comme ça :

SELECT dbo.fn_Get_NextWeekDay('2011-08-08', 6) 

Le "6" vient de the list of possible values vous pouvez définir pour DATEFIRST.

Vous pouvez obtenir n'importe quel autre jour de la semaine en modifiant le second paramètre en conséquence.

C'est la fonction:

IF OBJECT_ID('dbo.fn_Get_NextWeekDay') IS NOT NULL 
    DROP FUNCTION dbo.fn_Get_NextWeekDay 
GO 
CREATE FUNCTION dbo.fn_Get_NextWeekDay(
    @aDate DATETIME 
    , @dayofweek  INT 
    /* 
     @dw - day of the week 
     1 - Monday 
     2 - Tuesday 
     3 - Wednesday 
     4 - Thursday 
     5 - Friday 
     6 - Saturday 
     7 - Sunday 
    */ 
) 
RETURNS DATETIME 
AS 
/* 
    SELECT dbo.fn_Get_NextWeekDay('2011-08-08', 6) 
    SELECT dbo.fn_Get_NextWeekDay('2011-08-08', 1) 
*/ 
BEGIN 
    RETURN 
     DATEADD(day 
     , (@dayofweek + 8 - DATEPART(dw, @aDate) - @@DATEFIRST) % 7 
     , @aDate 
    ) 
END 
GO 

[EDIT] Cela pourrait être une autre solution. Cela devrait fonctionner dans toutes les langues:

IF OBJECT_ID('dbo.fn_NextWeekDay') IS NOT NULL 
    DROP FUNCTION dbo.fn_NextWeekDay 
GO 
CREATE FUNCTION dbo.fn_NextWeekDay(
    @aDate  DATE 
    , @dayofweek NVARCHAR(30) 
) 
RETURNS DATE 
AS 
/* 
    SELECT dbo.fn_NextWeekDay('2016-12-14', 'fri') 
    SELECT dbo.fn_NextWeekDay('2016-03-15', 'mon') 
*/ 
BEGIN 
    DECLARE @dx INT = 6 
    WHILE UPPER(DATENAME(weekday,@aDate)) NOT LIKE UPPER(@dayofweek) + '%' 
    BEGIN 

    SET @aDate = DATEADD(day,1,@aDate) 

    SET @dx=@dx-1 
    if @dx < 0 
    BEGIN 
     SET @aDate = NULL 
     BREAK 
    END 
    END 

    RETURN @aDate 

END 
GO 

Answer 2

Utilisez DATEPART pour obtenir le jour de la semaine d'aujourd'hui et d'ajouter la différence au jour de la semaine souhaitée à la date d'aujourd'hui.

Answer 3

Extrayez la fonction SQL DATEADD.

DATEADD (Transact-SQL)

que vous pouvez utiliser cette fonction avec DATEPART pour retourner la date correcte.

DATEPART (Transact-SQL)

Answer 4

DECLARE @Today date = 'TODAYS-DATE'; 
DECLARE @TodayNumber int = DATEPART(dw, @Today) -- Get the day number 
DECLARE @Saturday date = DATEADD(DAY, (6-@TodayNumber)%7, @Today) 
-- Add the number of days between today and saturday (the 6th day), modulus 7 to stop you adding negative days 

Hope that helps!

Answer 5

Essayez ceci:

SET DATEFIRST 7 
DECLARE @d DATETIME 
SET @d = '2011-08-08' --GETDATE() 

SELECT NEXT_SAT = DATEADD(day, (7 + @@DATEFIRST - DATEPART(dw, @d)) % 7, @d) 

Answer 6

Utilisez une table de calendrier (tableau avec une ligne par jour):

SELECT MIN(DateValue) DateValue 
FROM Calendar 
WHERE DateValue >= CURRENT_TIMESTAMP 
AND DayOfWeek = 'Saturday';