Conversion erreur DateTime lors de l'exécution procédure stockée SQL

Question

je l'ai écrit en suivant la procédure stockée:

GO 
/****** Object: StoredProcedure [dbo].[ReadCounters] Script Date: 08/17/2011 13:43:12 ******/ 
SET ANSI_NULLS ON 
GO 
SET QUOTED_IDENTIFIER ON 
GO 

-- ReadCounters -- 
ALTER PROCEDURE [dbo].[ReadCounters] 
    @type bit, 
    @startDate DateTime, 
    @endDate DateTime 
AS 
BEGIN 
    DECLARE 
    @AllCounterIds NVARCHAR(MAX), 
    @Query NVARCHAR(MAX); 

    SELECT @AllCounterIds = STUFF((
      SELECT DISTINCT '],[' + CAST([CounterId] AS VARCHAR(32)) 
      FROM AllCounters 
      WHERE [DateTime] > @startDate AND [DateTime] < @endDate AND [Type] = @type 
      for xml path('')), 1, 2, '') + ']'; 

    SET @Query = 'SELECT [DateTime], pvt.* from 
        (SELECT [Type], [DateTime], [Value], [CounterId] 
        FROM AllCounters WHERE CounterId IN 
         (
         SELECT DISTINCT([CounterId]) 
         FROM AllCounters 
         WHERE [DateTime] > '''+ @startDate +''' AND [DateTime] < '''+ @endDate +''' AND [Type] = '+ @type +' 
         ) AND [DateTime] > '''+ @startDate +''' AND [DateTime] < '''+ @endDate +''' AND [Type] = '+ @type +' 
        ) S 
       PIVOT 
       (
        SUM (Value) 
        FOR CounterId IN 
        (' + @AllCounterIds + ') 
       ) AS pvt;';   
    EXECUTE(@Query); 
END 

Maintenant, lorsque je tente d'exécuter cette SP en utilisant toute la manière suivante:

exec ReadCounters 1,'2013-10-05', '2011-11-30' 
exec ReadCounters 1,'2013-10-05 00:00:00', '2011-11-30 00:00:00' 
exec ReadCounters 1,'2013-10-05 00:00:00.000', '2011-11-30 00:00:00.000' 
exec ReadCounters 1,{ts '2013-10-05 00:00:00.000'}, {ts '2011-11-30 00:00:00.000'} 

i get suivantes erreur:

Msg 241, Level 16, State 1, Procedure ReadCounters, Line 19 
Conversion failed when converting date and/or time from character string. 

toute suggestion pourquoi me donne une erreur. Et si seulement exécuter la requête Select, il fonctionne parfaitement bien.

Answer 1

Vous avez besoin CONVERT bien sûr le formater

.... 
WHERE [DateTime] > '''+ CONVERT(varchar(30), @startDate, 120) +''' AND ... 
... 

Pourquoi SQL Server suppose que vous voulez concaténer différents types de données?

L'erreur est parce que NVARCHAR (MAX) est plus faible priorité alors datetime selon these rules

Answer 2

Je préférerais le faire - permet d'économiser beaucoup de conversions en désordre et les pauses rouge/noir (bien que je vais quand même recommander concaténation pour la liste séparée par des virgules des ID):

SET @Query = N'SELECT [DateTime], pvt.* from 
      (SELECT [Type], [DateTime], [Value], [CounterId] 
      FROM AllCounters WHERE CounterId IN 
       (
       SELECT DISTINCT([CounterId]) 
       FROM AllCounters 
       WHERE [DateTime] > @startDate AND [DateTime] < @endDate AND [Type] = @type 
       ) AND [DateTime] > @startDate AND [DateTime] < @endDate AND [Type] = @type 
      ) S 
      PIVOT 
      (
       SUM (Value) 
       FOR CounterId IN 
       (' + @AllCounterIds + ') 
      ) AS pvt;';   

EXEC sp_executesql @query, 
    N'@startDate DATETIME, @endDate DATETIME, @type BIT', 
    @startDate, @endDate, @type;