Comment est-ce que je peux lier à awesomium en utilisant cmake

Question

Je suis nouveau au développement en utilisant awesomium et j'essaye d'obtenir l'exemple de monde d'hélice fonctionnant dans Ubuntu. J'utilise CLion qui utilise CMake comme système de construction. Je me demandais comment lier avec succès à Awesomium en utilisant CMake.

Answer 1

I figured it out après une longue vague d'essais et d'erreurs:

CMakeList.txt:

cmake_minimum_required(VERSION 3.3) 
project(LetsChat) 

set (CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake") 

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11") 

set(SOURCE_FILES main.cpp) 

find_package (Awesomium REQUIRED) 
include_directories (${AWESOMIUM_INCLUDE_DIR}) 
add_executable(LetsChat ${SOURCE_FILES}) 

target_link_libraries(LetsChat ${AWESOMIUM_LIBRARY}) 

FindAwesomium.cmake (Sous-répertoire CMake)

include (FindPackageHandleStandardArgs) 

find_path(AWESOMIUM_INCLUDE_DIR Awesomium/WebCore.h 
     PATH_SUFFIXES include 
     PATHS 
     ${AWESOMIUM_ROOT} 
     $ENV{AWESOMIUM_ROOT} 
     ~/Library/Frameworks 
     /Library/Frameworks 
     /usr/local/ 
     /usr/ 
     /sw   # Fink 
     /opt/local/ # DarwinPorts 
     /opt/csw/ # Blastwave 
     /opt/) 

find_library(AWESOMIUM_LIBRARY 
     NAMES libawesomium-1-7.so 
     PATH_SUFFIXES lib64 lib build/lib 
     PATHS 
     ${AWESOMIUM_ROOT} 
     $ENV{AWESOMIUM_ROOT} 
     ~/Library/Frameworks 
     /Library/Frameworks 
     /usr/local/ 
     /usr/lib/ 
     /usr/ 
     /sw   # Fink 
     /opt/local/ # DarwinPorts 
     /opt/csw/ # Blastwave 
     /opt/) 

find_package_handle_standard_args (Awesomium DEFAULT_MSG AWESOMIUM_INCLUDE_DIR AWESOMIUM_LIBRARY) 
mark_as_advanced (AWESOMIUM_INCLUDE_DIR AWESOMIUM_LIBRARY) 

if (AWESOMIUM_FOUND) 
    message (STATUS "Found Awesomium: ${AWESOMIUM_INCLUDE_DIR}") 
endif()