variables d'interpolation et macro Chaîne

Question

Donner le code

class Test { 
    static function main() { 
    var i = 1; 
    trace(m('some before $i some after')); // some before 1 some after 
    } 

    static macro function m(e: haxe.macro.Expr) 
    { 
    trace(e); // { expr => EConst(CString(some before $i some after)), pos => #pos(Test.hx:4: characters 12-39) } 

    // trace the name of referenced var 
    /* 
    trace(); 
    */ 

    return macro $e; 
    } 
} 

Que dois-je placer dans le code commenté pour trace() le nom de la variable utilisée dans une expression String interpolée sans analyse syntaxique manuelle de la chaîne constante?

Answer 1

Qu'est-ce que vous voulez est formatString:

class Test { 
    #if !macro 
    static function main() { 
    var i = 1; 
    trace(m('some before $i some after')); // some before 1 some after 
    } 
    #end 
    static macro function m(e: haxe.macro.Expr) 
    { 
    switch e.expr { 
     case EConst(CString(s)): 
     trace(haxe.macro.MacroStringTools.formatString(s, e.pos)); 
     default: 
    } 
    return e; 
    } 
} 

Answer 2

L'expression en entrée est une chaîne littérale constante. Donc, vous devez analyser le $i vous-même. Voici un exemple utilisant un regular expression, et pour les points bonus, obtenez son type dans le contexte appelant.

http://try-haxe.mrcdk.com/#B0B9E (Cliquez Build+run, et voir à la fois la sortie et la sortie du compilateur onglets)

import haxe.macro.Expr; 
import haxe.macro.Context; 

class Test { 
    static function main() { 
    var i = 1; 
    trace(m('some before $i some after')); // some before 1 some after 
    } 

    static macro function m(e: Expr) 
    { 
    trace(e); // { expr => EConst(CString(some before $i some after)), pos => #pos(Test.hx:4: characters 12-39) } 

    var interpolated:String = null; 
    switch e.expr { 
     case EConst(CString(str)): 
     trace(str); // 'some before $i some after' 
     var r = ~/\$\w+/; 
     if (r.match(str)) { // matched(0) -> $i 
      interpolated = r.matched(0).substr(1); 
      trace(interpolated); // 'i' 
     } 
     default: throw 'Macro m expects a string literal...'; 
    } 

    if (interpolated!=null) { 
     var t = Context.typeof({expr: EConst(CIdent(interpolated)), pos:Context.currentPos()}); 
     trace('Got interpolated var $interpolated of type $t'); // Got interpolated var i of type TAbstract(Int,[]) 
    } 

    return macro $e; 
    } 
}