Modifier les limites d'une fenêtre

Question

J'ai besoin d'aide pour le script Apple. Je ne suis pas expert en la matière. Le script est le suivant:

(* 

This Apple script will resize any program window to an exact size and the window is then moved to the center of your screen. 
Specify the program name, height and width below and run the script. 

Written by Amit Agarwal on December 10, 2013 

*) 

set theApp to "Finder" 
set appHeight to 412 
set appWidth to 678 

tell application "Finder" 
    set screenResolution to bounds of window of desktop 
end tell 

set screenWidth to item 3 of screenResolution 
set screenHeight to item 4 of screenResolution 

tell application theApp 
    activate 
    reopen 
    set yAxis to (screenHeight - appHeight)/2 as integer 
    set xAxis to (screenWidth - appWidth)/2 as integer 
    set the bounds of the first window to {xAxis, yAxis, appWidth + xAxis, appHeight + yAxis} 
    tell application "Finder" to set the sidebar width of every Finder window to 142 
end tell 

Je voudrais redimensionner le Finder, mais sans le centrer sur l'écran. C'est possible?

Answer 1

La logique est, vous obtenez les limites actuelles de la fenêtre de devant. Les deux premiers éléments des limites sont le point horizontal de départ sur l'axe des x et le point vertical de départ sur l'axe des y. (en d'autres termes, les deux premiers éléments sont les coordonnées du coin supérieur gauche) Une fois que vous en avez, définissez de nouvelles limites, en conservant les deux premiers éléments de la description des limites, puis en ajoutant la largeur et la hauteur souhaitées le deuxième deux points pour redimensionner la fenêtre.

set theApp to "Finder" 
set appHeight to 412 
set appWidth to 678 

tell application theApp 
    activate 
    set {startHoriz, startVert, endHoriz, endVert} to bounds of the first window 
    set the bounds of the first window to {startHoriz, startVert, startHoriz + appWidth, startVert + appHeight} 
end tell 
tell application "Finder" to set the sidebar width of every Finder window to 142 

Si vous voulez déplacer la fenêtre tout le chemin à gauche, vous pouvez changer le startHoriz à 1 avant de fixer les limites de la fenêtre.