Coldfusion Requête MySQL dans une requête

Question

J'essaie de récupérer des enregistrements qui tombent dans une année et un mois spécifiques à partir d'un ensemble complet d'enregistrements récupérés pour un utilisateur particulier. Tout d'abord, le champ en question itemdate est MySql type Datetime (par exemple, 2016-08-15 20:00:25). Il y a 4 lignes d'enregistrements pour un utilisateur:

2016-08-15 20:00:25 
2015-06-01 20:25:05 
2016-08-15 20:26:00 
2016-08-15 23:30:35 

Ces enregistrements pour un utilisateur particulier sont récupérés par:

<cfquery datasource="userdatbase"name="reportlist"> 
select itemid, itemdate, itemvalue 
from itemlib 
where userid = '#currentuserid#' 
</cfquery> 

L'année en cours et mois est déterminé par:

<cfset thisyear = #Year(Now())#> 
<cfset thismonth = #Month(Now())#> 

Maintenant, filtrez la requête d'origine et obtenez seulement ceux de l'année et du mois en cours:

<cfquery dbtype="query" name="detail"> 
     select itemid, itemdate, itemvalue 
     from reportlist 
     where year(itemdate) = #thisyear# 
     and month(itemdate) = #thismonth# 
    </cfquery> 

Je reçois l'erreur suivante:

Erreur lors de l'exécution de la requête de base de données.

Erreur de syntaxe Query Of Queries. . Rencontrés « année expression conditionnelle incorrecte, prévue l'un des [comme | null | entre | en | comparaison] condition,

J'ai essayé de le faire à la place:

<cfquery dbtype="query" name="detail"> 
     select itemid, itemdate, itemvalue 
     from reportlist 
     where #year(reportlist.itemdate)# = #thisyear# 
     and #month(reportlist.itemdate)# = #thismonth# 
    </cfquery> 

qui va se débarrasser de l'erreur Cependant, j'ai obtenu toutes les 4 rangées d'enregistrements dans le détail requête au lieu du attendu 3. Je ne m'attends pas à ce que l'enregistrement 2015-06-01 20:25:05 soit sélectionné, mais il le fait. Je me gratte la tête dessus, toute aide est appréciée Merci d'avance

Answer 1

Une requête coldfusion de requêtes (QofQ) n'a pas toutes les fonctionnalités d'un dbms. year() n'est pas pris en charge dans la syntaxe QofQ.

Votre deuxième requête est syntaxiquement correct, car il passe à la valeur du reportlist.itemdate, qui sera la valeur de itemdate dans la première ligne de la requête reportlist (en supposant que vous n'êtes pas bouclez reportlist). ColdFusion interprète cela comme la comparaison de deux valeurs littérales au lieu de comparer les valeurs de ligne dans la requête.

Sinon, vous pouvez définir une variable (fromDate) à la première date du mois que vous voulez, puis filtrer votre requête lorsque la date de l'article est >= la fromDate et < fromDate plus 1 mois. Voir ci-dessous:

<!--- set fromDate to the first date of the month ---> 
<cfset fromDate = createDate(thisyear, thismonth, 1) /> 
<cfquery dbtype="query" name="detail"> 
    select itemid, itemdate, itemvalue 
    from reportlist 
    where itemdate >= <cfqueryparam value="#fromDate#" cfsqltype="cf_sql_date" /> 
      and itemdate < <cfqueryparam value="#dateAdd('m', 1, fromDate)#" cfsqltype="cf_sql_date" /> 
</cfquery> 

Cela permet d'obtenir la même chose en utilisant des comparateurs pris en charge dans ColdFusion QoQ.

Quelques documents utiles ici: http://help.adobe.com/en_US/ColdFusion/9.0/Developing/WSc3ff6d0ea77859461172e0811cbec0e4fd-7ff0.html