Comment puis-je faire en sorte que cette fonction AppleScript Folder Watch ignore les éléments masqués?

Question

J'ai passé mon dimanche entier à essayer de trouver une réponse à cette question et j'admets maintenant la défaite et je demande votre aide. J'ai lu plusieurs exemples ici et d'autres sites AppleScript, mais aucun d'entre eux ne semble fonctionner lorsqu'il est appliqué à ce script. Je me mets cependant à me le dire. J'essaie d'utiliser le script ci-dessous pour regarder un dossier puis m'envoyer un email quand un nouvel élément a été ajouté et ça fonctionne très bien. Le problème que j'éprouve c'est d'ignorer les dossiers système [ou cachés].

J'ai supprimé mes efforts pour ce faire, car ils ont tous continué à briser le tout, donc la version ci-dessous fonctionne, mais actuellement il comprendra des éléments cachés.

property theName : "Name" 
property theAddress : "name@company.com" 


on adding folder items to this_folder after receiving added_items 
    set added_Items_List to {} 
    repeat with oneItem in added_items 
     set end of added_Items_List to name of (info for oneItem) 
    end repeat 
    set {TID, text item delimiters} to {text item delimiters, ", "} 
    set added_Items_List to added_Items_List as text 
    set text item delimiters to TID 
    set dateString to (current date) as string 
    set theBody to "There are new files in the FTP folder " & name of (info for this_folder) & ":" & return & return & added_Items_List 
    tell application "Mail" 
     set newMessage to make new outgoing message with properties {visible:true, subject:"New submissions on FTP: " & dateString, content:theBody} 
     tell newMessage 
      make new to recipient at end of to recipients with properties {name:theName, address:theAddress} 
     end tell 
     activate 
     send newMessage 
    end tell 
end adding folder items to 

Toute aide ou direction serait très appréciée et j'espère que d'autres bénéficieront d'une solution de travail.

Pour tous ceux qui rencontrent ce post avec un problème similaire, vous pouvez trouver la réponse à votre problème dans l'un de ces messages.

• Applescript System Events Returns .DS_Store - How can I ignore
• How to I tell this Applescript to skip some files?
• AppleScript : How to get files in folder without hidden files?

Answer 1

fichiers cachés commencent par un point, filtrez simplement les articles

on adding folder items to this_folder after receiving added_items 
set added_Items_List to {} 
repeat with oneItem in added_items 
    set fileName to name of (info for oneItem) 
    if fileName does not start with "." then 
     set end of added_Items_List to fileName 
    end if 
end repeat 
if (count added_Items_List) = 0 then return 
.... 

Mais si le Finder sur votre machine ne pas montrer le fichiers cachés par défaut, vous n'avez pas besoin des lignes supplémentaires.