delphi - Faire défiler horizontalement sur le mouvement de la souris en douceur

Question

J'ai un formulaire avec une barre de défilement horizontale, mais je veux supprimer la barre de défilement en utilisant le mouvement de la souris (horizaontally) sur le formulaire comme un moyen de défilement. Je veux qu'avec le mouvement de la souris ma forme défile mais sans décalage et doucement et quand j'atteins la fin elle arrête de défiler. Donc, si quelqu'un pouvait m'aider, ce serait une aide énorme. Merci d'avance.

Answer 1

Cela fait bien l'écran se déplaçant bien sur 10.1 Berlin tant que vous ne cachez pas les barres de défilement. La documentation suggère que cela devrait fonctionner si vous masquez les barres de défilement, donc peut-être sur une version antérieure de Delphi.

OnMouseDown, OnMouseMove et OnMouseUp sont utilisés, ainsi que 3 variables locales.

unit Unit10; 

interface 

uses 
    Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics, 
    Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, System.StrUtils, Vcl.Mask; 

type 
    TForm10 = class(TForm) 
    Edit1: TEdit; 
    Edit2: TEdit; 
    Button1: TButton; 
    procedure FormMouseDown(Sender: TObject; Button: TMouseButton; 
     Shift: TShiftState; X, Y: Integer); 
    procedure FormMouseUp(Sender: TObject; Button: TMouseButton; 
     Shift: TShiftState; X, Y: Integer); 
    procedure FormMouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer); 
    private 
    { Private declarations } 
    fIsDown : boolean; 
    fX, fY : integer; 
    public 
    { Public declarations } 
    end; 

var 
    Form10: TForm10; 

implementation 

{$R *.dfm} 

procedure TForm10.FormMouseDown(Sender: TObject; Button: TMouseButton; 
    Shift: TShiftState; X, Y: Integer); 
begin 
    if Shift = [ssLeft] then // if ONLY left down 
    begin 
    // Save co-ordinates 
    fIsDown := TRUE; 
    fX := X; 
    fY := Y; 
    end; 
end; 

procedure TForm10.FormMouseMove(Sender: TObject; Shift: TShiftState; X, 
    Y: Integer); 
begin 
    if Shift = [ssLeft] then // if ONLY left down 
    begin 
    if fIsDown then 
    begin 
     HorzScrollBar.Position := HorzScrollBar.Position + fX - X; 
     VertScrollBar.Position := VertScrollBar.Position + fY - Y; 
    end 
    else 
    begin 
     fIsDown := TRUE; 
    end; 
    fX := X; 
    fY := Y; 
    end 
    else 
    begin 
    fIsDown := FALSE; 
    end; 
end; 

procedure TForm10.FormMouseUp(Sender: TObject; Button: TMouseButton; 
    Shift: TShiftState; X, Y: Integer); 
begin 
    fIsDown := FALSE; // regardless of shift state! 
end; 

end. 

S'il vous plaît laissez-nous savoir si cacher les barres de défilement fonctionne sur XE8, car cela serait utile pour les futurs lecteurs.