fmap sur la fonction variable d'arguments

Question

Je voudrais définir fmap sur les fonctions d'arguments variables:

type family VarArg (args :: [*]) e where 
    VarArg '[] e = e 
    VarArg (a ': as) e = a -> VarArg as e 

mapVarArg :: forall args e e' 
      . (e -> e') -> VarArg args e -> VarArg args e' 
mapVarArg f = _ 

C'est la solution la plus proche que j'ai trouvé:

mapVarArg :: forall args e e' . VarArgIso args 
      => (e -> e') -> VarArg args e -> VarArg args e' 
mapVarArg f = (^. Lens.from varArgIso) . fmap f . (^. varArgIso @args) 

data VarArgD (args :: [*]) e where 
    DNil :: e -> VarArgD '[] e 
    DCons :: (a -> VarArgD as e) -> VarArgD (a ': as) e 

class VarArgIso (args :: [*]) where 
    varArgIso :: Iso' (VarArg args e) (VarArgD args e) 

instance VarArgIso '[] where 
    varArgIso = iso DNil (\(DNil x) -> x) 

instance VarArgIso as => VarArgIso (a ': as) where 
    varArgIso = iso (\f -> DCons ((^. varArgIso) . f)) (\(DCons f) -> ((^. Lens.from varArgIso) . f)) 

instance Functor (VarArgD args) where 
    fmap f (DNil a) = DNil (f a) 
    fmap f (DCons g) = DCons (fmap f . g) 

est-il une solution plus simple, ou tout solution sans contrainte supplémentaire VarArgIso?

Answer 1

Je pense que les solutions sans modèle ne sont pas possibles sans contraintes de classe supplémentaires. Il y a une mise en œuvre simple et probablement efficace avec les instances qui se chevauchent:

class VarArg a b c d where 
    mapVarArg :: (a -> b) -> c -> d 

instance (a ~ c, b ~ d) => VarArg a b c d where 
    mapVarArg = id 

instance {-# overlapping #-} (VarArg a b c2 d2, c1 ~ d1) => 
    VarArg a b (c1 -> c2) (d1 -> d2) where 
    mapVarArg f g = mapVarArg f . g 

Si vous remplacez overlapping avec incoherent, cela fonctionne aussi généralement des fonctions polymorphes/contraintes comme arguments:

> mapVarArg (+100) (+) 0 0 
100 

Cependant, avec le incoherent instance, partiellement appliquée mapVarArg -s ont tendance à avoir des types déduits inutilisables.

> let foo = mapVarArg (+100) (+) 
> :t foo 
foo :: (Num (a -> a -> a), Num a) => a -> a -> a