SAS essayant d'obtenir la différence en jours de orderdate à shipdate

Question

J'utilise le jeu de données adventureworks.

Vous cherchez des méthodes pour calculer en moyenne combien de temps faut-il à ADW pour livrer les produits entre la date de commande et la date d'expédition.

format date s9.

.: par exemple

orderdate    shipdate 
01JUL2005:00:00:00 08JUL2005:00:00:00 

Answer 1

Voilà une approche qui pourrait aider. La fonction SAS intck() est très utile!

/* Generate a dataset as described. */ 
    data have; 
     do id=1 to 10000; 
      orderdate = today()-(ceil(ranuni(id)*1000)); 
      shipdate = orderdate + ceil(ranuni(id)*10); 
      output; 
     end; 
     format orderdate shipdate date9.; 
    run; 

/* Use intck() to count the number of days or weekdays between order and delivery dates */ 
    data want; 
     set have; 
     weekdays_passed = intck('weekday7w',orderdate,shipdate); 
     abs_days_passed = intck('day',orderdate,shipdate); 
    run; 

/* Two ways to obtain average delivery time in days. */ 
/*1*/ 
    proc univariate data=want; 
     var weekdays_passed 
      abs_days_passed; 
    run; 
/*2*/ 
    proc sql; 
     select avg(weekdays_passed) as avg_weekdays_passed, 
       avg(abs_days_passed) as avg_abs_days_passed 
     from want; 
    quit;