Conversion de texte brut en listes de style html en utilisant xstl, ou regroupement d'éléments en fonction de leur contenu et de leur position en utilisant xslt

Question

En essayant de convertir un document en texte brut en document html en utilisant xslt, je suis aux prises avec des listes non ordonnées.

J'ai:

<item>some text</item> 
<item>- a list item</item> 
<item>- another list item</item> 
<item>more plain text</item> 
<item>more and more plain text</item> 
<item>- yet another list item</item> 
<item>even more plain text</item> 

Ce que je veux:

<p>some text</p> 
<ul> 
    <li>a list item</li> 
    <li>another list item</li> 
</ul> 
<p>more plain text</p> 
<p>more and more plain text</p> 
<ul> 
    <li>yet another list item</li> 
</ul> 
<p>even more plain text</p> 

Je regardais le Muenchian groupant mais il combinerait tous les éléments de la liste dans un groupe et tous les éléments de texte brut dans une autre . Ensuite, j'ai essayé de ne sélectionner que les éléments dont le premier élément précédent est différent de son premier caractère. Mais quand j'essaie de tout combiner, je reçois tout le li dans un ul.

Avez-vous des conseils pour moi?

Answer 1

Cette transformation:

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:key name="kFollowing" 
    match="item[contains(., 'list')] 
      [preceding-sibling::item[1][contains(.,'list')]]" 
    use="generate-id(preceding-sibling::item 
         [not(contains(.,'list'))] 
         [1] 
         /following-sibling::item[1] 
        )"/> 

<xsl:template match="item[contains(.,'list')] 
       [preceding-sibling::item[1][not(contains(.,'list'))]]"> 

    <ul> 
    <xsl:apply-templates mode="list" 
     select=".|key('kFollowing',generate-id())"/> 
    </ul> 
</xsl:template> 

<xsl:template match="item" mode="list"> 
    <li><xsl:value-of select="."/></li> 
</xsl:template> 

<xsl:template match="item[not(contains(.,'list'))]"> 
    <p><xsl:value-of select="."/></p> 
</xsl:template> 

<xsl:template match="item[contains(.,'list')] 
       [preceding-sibling::item[1][contains(.,'list')]]"/> 
</xsl:stylesheet> 

lorsqu'il est appliqué sur le document XML fourni (corrigé à partir sévèrement malformés dans un document XML bien formé):

<t> 
<item>some text</item> 
<item>- a list item</item> 
<item>- another list item</item> 
<item>more plain text</item> 
<item>more and more plain text</item> 
<item>- yet another list item</item> 
<item>even more plain text</item> 
</t> 

produit le voulait , résultat correct:

<p>some text</p> 
<ul> 
    <li>- a list item</li> 
    <li>- another list item</li> 
</ul> 
<p>more plain text</p> 
<p>more and more plain text</p> 
<ul> 
    <li>- yet another list item</li> 
</ul> 
<p>even more plain text</p> 

Answer 2

Cette feuille de style:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output indent="yes"/> 
    <xsl:strip-space elements="*"/> 
    <xsl:template match="node()"> 
     <xsl:apply-templates select="node()[1]|following-sibling::node()[1]"/> 
    </xsl:template> 
    <xsl:template match="item"> 
     <p> 
      <xsl:value-of select="."/> 
     </p> 
     <xsl:apply-templates select="following-sibling::node()[1]"/> 
    </xsl:template> 
    <xsl:template match="item[starts-with(.,'- ')]"> 
     <ul> 
      <xsl:call-template name="open"/> 
     </ul> 
     <xsl:apply-templates 
      select="following-sibling::node() 
         [not(self::item[starts-with(.,'- ')])][1]"/> 
    </xsl:template> 
    <xsl:template match="node()" mode="open"/> 
    <xsl:template match="item[starts-with(.,'- ')]" mode="open" name="open"> 
     <li> 
      <xsl:value-of select="substring-after(.,'- ')"/> 
     </li> 
     <xsl:apply-templates select="following-sibling::node()[1]" mode="open"/> 
    </xsl:template> 
</xsl:stylesheet> 

Sortie:

<p>some text</p> 
<ul> 
    <li>a list item</li> 
    <li>another list item</li> 
</ul> 
<p>more plain text</p> 
<p>more and more plain text</p> 
<ul> 
    <li>yet another list item</li> 
</ul> 
<p>even more plain text</p> 

Remarque: C'est comme emballage adjacents. Ussing traversal à grain fin.