Classe parent dans une autre classe

Question

Ok, donc j'ai cette classe, disons CMain, qui contient une classe CFruit. Ce que je voudrais faire est d'exécuter des fonctions basées sur le type de CFruit (si c'est CPear ou CApple, etc). Je voudrais donc faire quelque chose comme ceci:

type CMain = class 
    myFruit : CFruit; 
    function GetFruit() : CFruit; 
    procedure SetFruit(Fruit : CFruit); 
end; 

procedure CMain.SetFruit(Fruit : CFruit); 
begin 
    if Fruit.IsPear then .. else etc; 
end; 

... évidemment le compilateur me empêche de faire cela parce que CFruit est juste parent de CPear et Capple. Y a-t-il un moyen viable de le faire? (Il est hors de question que CMain soit séparé). Merci.

Answer 1

Voici un exemple pour l'utilisation de méthodes virtuelles:

type 
TFruit = class 
public 
    procedure doSomethingFruitSpecific; virtual; abstract; 
end; 

TPear = class(TFruit) 
public 
    procedure doSomethingFruitSpecific; override; 
end; 

TApple = class(TFruit) 
public 
    procedure doSomethingFruitSpecific; override; 
end; 

TMain = class 
    procedure SetFruit(Fruit : TFruit); 
end; 

implementation 

procedure TMain.SetFruit(Fruit : TFruit); 
begin 
    Fruit.doSomethingFruitSpecific; 
end; 

procedure TApple.doSomethingFruitSpecific; 
begin 
    Writeln('bake an apple pie'); 
end; 

procedure TPear.doSomethingFruitSpecific; 
begin 
    Writeln('pick some pears'); 
end; 

Answer 2

IIUC vous voulez virtual methods.

Answer 3

En fait, il y a un « est » opérateur, qui vérifiera si l'objet est une instance de classe ou il est ancêtres. Ceci est appelé "vérification de type dynamique" et est en cours de développement. Consultez l'aide pour une clarification.

En fonction de vos besoins, les "méthodes virtuelles" pourraient être ce dont vous avez besoin, comme expliqué par d'autres. S'il vous plaît vérifier le lien posté sur "méthodes virtuelles" comme la bonne méthode OOP.

Dans l'exemple ci-dessous

if AFruit is TApple then 

et

if AFruit is TFruit then 

deux return true

type 
    TFruit = class 
    protected 
    FName: string; 
    public 
    property Name: string read FName; 
    end; 

    TApple = class(TFruit) 
    public 
    constructor Create; 
    end; 

    TPear = class(TFruit) 
    public 
    constructor Create; 
    end; 

    TForm1 = class(TForm) 
    Button1: TButton; 
    mixed: TLabel; 
    procedure Button1Click(Sender: TObject); 
    private 
    { Private declarations } 
    FMixValue: string; 
    procedure MixFruits(AFruit: TFruit); 
    public 
    { Public declarations } 
    end; 

var 
    Form1: TForm1; 

implementation 

{$R *.dfm} 

procedure TForm1.Button1Click(Sender: TObject); 
var 
    APear: TPear; 
    AApple : TApple; 
begin 
    APear := TPear.Create; 
    AApple := TApple.Create; 
    MixFruits(APear); 
    MixFruits(AApple); 
    mixed.Caption := FMixValue; 
end; 

{ TPear } 

constructor TPear.Create; 
begin 
    inherited; 
    FName := 'Pear'; 
end; 

{ TApple } 

constructor TApple.Create; 
begin 
    inherited; 
    FName := 'Apple'; 
end; 

procedure TForm1.MixFruits(AFruit: TFruit); 
begin 
    FMixValue := FMixValue + ' ' + AFruit.Name; 
    if AFruit is TApple then 
    ShowMessage('An Apple') 
    else if AFruit is TPear then 
    ShowMessage('A Pear') 
    else 
    ShowMessage('What is it?'); 
end;